Using VBA in Excel to Open Outlook

Option Explicit
Private Sub Workbook_Open()
'   Opens Outlook Application, creates and displays an email with activeworkbook as attachment
    
    Dim olkApp As Outlook.Application
    Dim olkNameSpace As Outlook.NameSpace
    Dim olkDefaultFolder As Outlook.MAPIFolder
    Dim olkMail As Outlook.MailItem
    
'   If Outlook isn't open, open it
    On Error Resume Next
    Set olkApp = GetObject(, "Outlook.Application")
    If Err.Number <> 0 Then Set olkApp = CreateObject("Outlook.Application")
    
    On Error GoTo 0
    
    Set olkNameSpace = olkApp.GetNamespace("MAPI")
    Set olkDefaultFolder = olkNameSpace.GetDefaultFolder(Outlook.olFolderInbox)
    Set olkMail = olkDefaultFolder.Items.Add(Outlook.olMailItem)
    
'   Use of CreateItem can cause run-time permission error -2044526587
    'Set olkMail = olkApp.CreateItem(Outlook.olMailItem)
    
'   Display mail message
    With olkMail
        .To = "bgmarston@gmail.com"
        .CC = ""
        .BCC = ""
        .Subject = "This is the Subject line"
        .Body = "Hi there"
        .Attachments.Add ActiveWorkbook.FullName
        .Display 'Use .Send to send
    End With
    
'   Release variables
    Set olkMail = Nothing
    Set olkDefaultFolder = Nothing
    Set olkNameSpace = Nothing
    Set olkApp = Nothing
    
End Sub