Macro to change a Macro Code

Sub SwapProcs()
    Dim wbkToChange As Workbook
    Dim VBProj As VBProject, VBComp As VBComponent
    Const strMod As String = "Getinfo"
    Const strProc As String = "Getdata"
    Dim strNewProc As String
    
    Set wbkToChange = Workbooks("KyleTest")
    'assume workbook already open (and that VBAProject is unlocked)
    
    Set VBProj = wbkToChange.VBProject
    Set VBComp = VBProj.VBComponents(strMod)
    strNewProc = "Sub Getdata()" & Chr(13) & _
        " Msgbox ""Your new data here"" " & Chr(13) & _
        "End Sub"
    'data re the code to be changed

    Call DeleteProcedure(VBComp, strProc)
    'remove old routine
    
    Call AddProcedure(VBComp, strNewProc)
    'add new routine

End Sub

Sub DeleteProcedure(VBComp As VBComponent, strProc As String)
    Dim VBCodeMod As CodeModule
    Dim StartLine As Long
    Dim HowManyLines As Long
    
    Set VBCodeMod = VBComp.CodeModule
    With VBCodeMod
        StartLine = .ProcStartLine(strProc, vbext_pk_Proc)
        HowManyLines = .ProcCountLines(strProc, vbext_pk_Proc)
        .DeleteLines StartLine, HowManyLines
    End With

End Sub

Sub AddProcedure(VBComp As VBComponent, strProc As String)
    Dim VBCodeMod As CodeModule
    Dim LineNum As Long
    
    Set VBCodeMod = VBComp.CodeModule
    With VBCodeMod
        LineNum = .CountOfLines + 1
        .InsertLines LineNum, strProc
    End With

End Sub