Print Macro

[isis]

Hi There,

I have a print macro that users run to select which sheets of a workbook they want to print. ( The code came from this forum a while back and I tailored it to suit my needs). The macro works fine, the only slight (but annoying) problem being that after the macro has run, it kicks the user out of the worksheet they were in and into a different sheet (Sheet 7). If the macro is run from sheet 7 then the user remains in this sheet but any other sheet bumps the user into sheet 7 and I can't for the life of me figure out why - or how to correct it. Surely CurrentSheet.Activate should take the user back to their current screen? But it doesn't. Can anyone suggest a remedy?

I've copied the code below in case it helps.

Thanks.

------------------


Sub PRINT_SHEETS()
Dim sh As Worksheet

Application.ScreenUpdating = True

Dim i As Integer
Dim TopPos As Integer
Dim SheetCount As Integer
Dim PrintDlg As DialogSheet
Dim CurrentSheet As Worksheet
Dim cb As CheckBox
Application.ScreenUpdating = False

' Check for protected workbook
If ActiveWorkbook.ProtectStructure Then
MsgBox "Workbook is protected.", vbCritical
Exit Sub
End If

' Add a temporary dialog sheet
Set CurrentSheet = ActiveSheet
Set PrintDlg = ActiveWorkbook.DialogSheets.Add

SheetCount = 0

' Add the checkboxes
TopPos = 40
For i = 1 To ActiveWorkbook.Worksheets.Count
Set CurrentSheet = ActiveWorkbook.Worksheets(i)
' Skip empty sheets and hidden sheets

If Application.CountA(CurrentSheet.Cells) <> 0 And _
CurrentSheet.Visible = xlSheetVisible Then
SheetCount = SheetCount + 1
PrintDlg.CheckBoxes.Add 78, TopPos, 150, 16.5
PrintDlg.CheckBoxes(SheetCount).Text = _
CurrentSheet.Name
TopPos = TopPos + 13
End If
Next i

' Move the OK and Cancel buttons
PrintDlg.Buttons.Left = 240

' Set dialog height, width, and caption
With PrintDlg.DialogFrame
.Height = Application.Max(68, PrintDlg.DialogFrame.Top + TopPos - 34)
.Width = 230
.Caption = "Select sheets to print"
End With

' Change tab order of OK and Cancel buttons
' so the 1st option button will have the focus
PrintDlg.Buttons("Button 2").BringToFront
PrintDlg.Buttons("Button 3").BringToFront

' Display the dialog box
CurrentSheet.Activate
Application.ScreenUpdating = True
If SheetCount <> 0 Then
If PrintDlg.Show Then
For Each cb In PrintDlg.CheckBoxes
If cb.Value = xlOn Then
Worksheets(cb.Caption).Activate
ActiveSheet.PrintOut
' ActiveSheet.PrintPreview 'for debugging
End If
Next cb
End If
Else
MsgBox "All worksheets are empty."
End If

' Delete temporary dialog sheet (without a warning)
Application.DisplayAlerts = False
PrintDlg.Delete

' Reactivate original sheet
CurrentSheet.Activate

Application.ScreenUpdating = True


-------------------

 

[Richie(UK)]

Hi,

Although the CurrentSheet variable is set to the ActiveSheet at the start of the code it is subsequently changed during the For ... Next loop that counts the worksheets. I would recommend using a For Each ... Next loop instead using the sh worksheet variable (which although declared does not appear to be used in the routine ) or using another variable for the activesheet at the time the routine is invoked,eg.

Sub SelectSheets()
    Dim i As Integer
    Dim TopPos As Integer
    Dim SheetCount As Integer
    Dim PrintDlg As DialogSheet
    Dim CurrentSheet As Worksheet
    Dim wsAS As Worksheet
    Dim cb As CheckBox
    Application.ScreenUpdating = False

'   Check for protected workbook
    If ActiveWorkbook.ProtectStructure Then
        MsgBox "Workbook is protected.", vbCritical
        Exit Sub
    End If

'   Add a temporary dialog sheet
    Set wsAS = ActiveSheet
    Set PrintDlg = ActiveWorkbook.DialogSheets.Add

    SheetCount = 0

'   Add the checkboxes
    TopPos = 40
    For i = 1 To ActiveWorkbook.Worksheets.Count
        Set CurrentSheet = ActiveWorkbook.Worksheets(i)
'       Skip empty sheets and hidden sheets
        If Application.CountA(CurrentSheet.Cells) <> 0 And _
            CurrentSheet.Visible Then
            SheetCount = SheetCount + 1
            PrintDlg.CheckBoxes.Add 78, TopPos, 150, 16.5
                PrintDlg.CheckBoxes(SheetCount).Text = _
                    CurrentSheet.Name
            TopPos = TopPos + 13
        End If
    Next i

'   Move the OK and Cancel buttons
    PrintDlg.Buttons.Left = 240

'   Set dialog height, width, and caption
    With PrintDlg.DialogFrame
        .Height = Application.Max _
            (68, PrintDlg.DialogFrame.Top + TopPos - 34)
        .Width = 230
        .Caption = "Select sheets to print"
    End With

'   Change tab order of OK and Cancel buttons
'   so the 1st option button will have the focus
    PrintDlg.Buttons("Button 2").BringToFront
    PrintDlg.Buttons("Button 3").BringToFront

'   Display the dialog box
    CurrentSheet.Activate
    Application.ScreenUpdating = True
    If SheetCount <> 0 Then
        If PrintDlg.Show Then
            For Each cb In PrintDlg.CheckBoxes
                If cb.Value = xlOn Then
                    Worksheets(cb.Caption).Activate
                    ActiveSheet.PrintOut
'                   ActiveSheet.PrintPreview 'for debugging
                End If
            Next cb
        End If
    Else
        MsgBox "All worksheets are empty."
    End If

'   Delete temporary dialog sheet (without a warning)
    Application.DisplayAlerts = False
    PrintDlg.Delete

'   Reactivate original sheet
    wsAS.Activate
End Sub

Also, you may have seen the code here on the forum but it looks suspiciously like the JWalk routine to me :wink:

http://www.j-walk.com/ss/excel/tips/tip48.htm

 

[George J]

Just make these small changes.

' Add a temporary dialog sheet
Set CurrentSheet = ActiveSheet
x = CurrentSheet.Name
Set PrintDlg = ActiveWorkbook.DialogSheets.Add

and

' Reactivate original sheet
Sheets(x).Select

Just the 2 lines needed a tweak.

 

[isis]

Thanks Guys

That macro works great now.

Isis

 

[Iridium]

Just for info here's the original

http://j-walk.com/ss/excel/tips/tip48.htm

 

[Richie(UK)]

Just for info here's the original

http://j-walk.com/ss/excel/tips/tip48.htm

Is this somehow different to the link I provided above?

Also, you may have seen the code here on the forum but it looks suspiciously like the JWalk routine to me :wink:

http://www.j-walk.com/ss/excel/tips/tip48.htm

 

[Iridium]

Richie

Nope its not - obviously not enough coffee for me this Sunday morning!

 

[Richie(UK)]

(PS: Can you ever have 'enough' coffee? :wink: )

 

[Iridium]

Agreed Richie. btw your Avatar is a caffeine molecule isn't it?

 

[smithj83]

Print Macro (Additional Question)

How would you tweak this macro so that when you click the command button, your hidden worksheets are in the list of sheets that can be printed as well as the active non-hidden sheets?

Thanks in advance for any assistance.