Find and Replace Series

Public Sub RngRepWith(Rng As Range, vRep As Variant, vWith As Variant, _
                      Optional bPart As Boolean)
   If Not IsArray(vRep) Then vRep = Array(vRep)                   'Make sure entries are arrays
   If Not IsArray(vWith) Then vWith = Array(vWith)
   Dim dDict As Object, vRng As Variant
   Dim i As Long, j As Long, e As Variant
   Set dDict = CreateObject("Scripting.Dictionary")
   For i = LBound(vRep) To UBound(vRep)                           'Assign arrays to dictionary
      dDict(vRep(i)) = vWith(i)                                   'where vRep is the Key
   Next i
   vRng = Rng.Value                                               'Write the range to an array
   For i = 1 To UBound(vRng, 1)                                   'Let i be the row num
      For j = 1 To UBound(vRng, 2)                                'and j the col num
         If bPart Then                                            'If we want partial matches,
            For Each e In dDict.Keys                              'then loop thru the keys
               If InStr(1, vRng(i, j), e, 1) Then                 'and if the rng entry includes
                  vRng(i, j) = Replace$(vRng(i, j), e, dDict(e))  'the key, then replace it
               End If                                             'with the dict item
            Next e
         Else                                                     'If we don't want partials,
            If dDict.Exists(vRng(i, j)) Then                      'then as long as the vRep
               vRng(i, j) = dDict(vRng(i, j))                     'exists, we can replace it
            End If
         End If
      Next j
   Next i
   Rng.Value = vRng
   Set dDict = Nothing
End Sub

dim rData as range, rFindAndReplaces as range
set rData = ...
set rFindAndReplaces = ...
RngRepWith rData, rFindAndReplaces.Columns(1), _
                 rFindAndReplaces.columns(2), true

RngRepWith rData, rFindAndReplaces.Columns(1).value, _
                  rFindAndReplaces.columns(2).value, true