removing the X from the userform

[brettvba]

How is this done?

[James]

Hi Brett,
Remove or disable?

James

[brettvba]

either or but i would like to know how to remove it aswell

[James]

Well to disable:

Private Sub UserForm_QueryClose _
(Cancel As Integer, CloseMode As Integer)
If CloseMode = vbFormControlMenu Then
MsgBox"You can't close the form like that."
Cancel = True
End If
End Sub

I have the code to remove the X, if you need
it i will look it up.

James

[brettvba]

That would be great thanks(removale Code)

[James]

I'm looking for it, it may take a while to find it.

James

[Mark O'Brien]

You can disable it or remove it. This example shows how to disable it and it appears "greyed out".

http://www.mrexcel.com/board/viewtop...c=5225&forum=2

If you really want to know how to remove I can knock up that code as well.

[brettvba]

could you knock up that code aswell that would be great mark!

[James]

Hi Brett,
I found it, you can either e-mail me an address to send it to you or go to:
http://www.bmsltd.co.uk/excel/default.htm

James

[Mark O'Brien]

James is right, that's a great site, that's where I pulled the code from for disabling the close button. I didn't even change the comments.

Anyway, here's the code to get rid of the X button.

Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long

Private Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long) As Long

Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long



Private Const GWL_STYLE As Long = (-16)           'The offset of a window's style

Private Const WS_SYSMENU As Long = &H80000        'Style to add a system menu





Private Sub UserForm_Initialize()

        RemoveCloseButton

End Sub

Private Sub RemoveCloseButton()

  Dim iStyle As Long

  Dim hWndForm As Long

  

      If Val(Application.Version) < 9 Then

        hWndForm = FindWindow("ThunderXFrame", Me.Caption)  'XL97

    Else

        hWndForm = FindWindow("ThunderDFrame", Me.Caption)  'XL2000

    End If

  

    'Get the basic window styles

    iStyle = GetWindowLong(hWndForm, GWL_STYLE)

    iStyle = iStyle And Not WS_SYSMENU

    

    'Set the basic window styles

    SetWindowLong hWndForm, GWL_STYLE, iStyle

End Sub

HTH