Autofilter - how can you display selected filter in another

[grienerth]

Is there a way to display the filter to another cell when using autofilter ?

[Ivan F Moala]

On 2002-05-20 17:48, grienerth wrote:
Is there a way to display the filter to another cell when using autofilter ?

Do you mean Display what filter criteria that is in use ??
If so then this code may help
Just place the UDF in a cell
=FilterCriteria(A2:A20) or what ever the
range is;
The code Orig from Stephen Bullen

Function FilterCriteria(Rng As Range) As String

    'By Stephen Bullen

    Dim Filter As String

    Filter = ""

    On Error GoTo Finish

    With Rng.Parent.AutoFilter

        If Intersect(Rng, .Range) Is Nothing Then GoTo Finish

        With .Filters(Rng.Column - .Range.Column + 1)

            If Not .On Then GoTo Finish

            Filter = .Criteria1

            Select Case .Operator

                Case xlAnd

                    Filter = Filter & " AND " & .Criteria2

                Case xlOr

                    Filter = Filter & " OR " & .Criteria2

            End Select

        End With

    End With

Finish:

    FilterCriteria = Filter

End Function