add item in combobox without duplicated or blanks with table

[abdelfattah]

hello
I have this code but the problem shows the duplicated items or blanks so what I would modified and doesn't show duplicated or blanks items

Private Sub UserForm_Initialize()
    Const COL_NUM As Integer = 2 ' Which column you want to access '

    Dim ws As Worksheet
    Dim i As Long
    Dim tbl As ListObject

    Set ws = sheet5

    Set tbl = ws.ListObjects("CustInfo")

    ComboBox1.Clear

    With tbl
       ' Add cell values one at a time to the Combo Box List
       For i = 1 To tbl.DataBodyRange.Rows.Count
           ComboBox1.AddItem tbl.DataBodyRange.Cells(i, COL_NUM)
       Next
    End With

end sub

 

[Fluff]

How about

    With CreateObject("scripting.dictionary")
       ' Add cell values one at a time to the Combo Box List
       For i = 1 To tbl.DataBodyRange.Rows.Count
         If tbl.DataBodyRange.Cells(i, COL_NUM) <> "" Then
            .Item(tbl.DataBodyRange.Cells(i, COL_NUM)) = Empty
         End If
       Next
       Me.ComboBox1.List = .Keys
    End With

 

[abdelfattah]

hi
it 's empty the combobox doesn't show anything
this is the code

Private Sub UserForm_Initialize()
    Const COL_NUM As Integer = 2 ' Which column you want to access '
    Dim ws As Worksheet
    Dim i As Long
    Dim tbl As ListObject
    Set ws = sheet5
    Set tbl = ws.ListObjects("CustInfo")
    ComboBox1.Clear

    With CreateObject("scripting.dictionary")
       ' Add cell values one at a time to the Combo Box List
       For i = 1 To tbl.DataBodyRange.Rows.Count
         If tbl.DataBodyRange.Cells(i, COL_NUM) <> "" Then
            .Item(tbl.DataBodyRange.Cells(i, COL_NUM)) = Empty
         End If
       Next
       Me.ComboBox1.List = .Keys
    End With
End Sub

 

[Fluff]

Try

            .Item(tbl.DataBodyRange.Cells(i, COL_NUM).Value) = Empty

 

[abdelfattah]

perfect ! many thanks for your assistance

 

[Fluff]

You're welcome & thanks for the feedback.