Add sheets to array and select

[Justice98]

Hello All,

I got 5 sheets with different tabcolors. The tab of a sheet becomes red when a certain value on the sheet isn't met. When it is, it becomes green. The only sheets I want to select as an array are the green sheets. How can I do this?
For example:
Sheet 1 tab color = Green
Sheet 2 tab color = Red
Sheet 3 tab color = Green
Sheet 4 tab color = Red
Sheet 5 tab color = Green

In the example I just want to select sheets 1, 3 and 5. But the color can change based on the cell value. So how can I do this based on the cell value or tabcolor?

 

[Fluff]

How about

Sub justice()
   Dim Ws As Worksheet
   
   With CreateObject("scripting.dictionary")
      For Each Ws In Worksheets
         If Ws.Tab.Color = 5287936 Then .Item(Ws.Name) = Empty
      Next Ws
      Sheets(.keys).Select
   End With
End Sub

change the 5287936 to match the green you are using

 

[veyselemre]

Sub test2()
    Dim tbs$, i&
    For i = 1 To Sheets.Count
        With Sheets(i)
            'If .Tab.Color = vbGreen Then
            If .Tab.Color = ActiveCell.Interior.Color Then
                tbs = tbs & "," & .Name
            End If
        End With
    Next i
    If tbs <> "" Then Sheets(Split(Mid(tbs, 2), ",")).Select
End Sub

 

[Justice98]

Hello Fluff and veyselemre,

Thank you both for the fast replies and your VBA Codes, they work perfect! I couldn't figure it out myself.

Kinds regards,

Justin

 

[Fluff]

Glad we could help & thanks for the feedback.