adding and subtracting from same cell with leaving the value inserted cell empty for later addition and subtraction

[siddheshmumbaikar]

VBA code would be appreciated.
for eg. D1 has value of 100. if i insert 10 in F1 it should get subtracted from D1 leaving F1 empty for later subractions. and if i insert say 20 in cell G1 it should get added in D1 leaving cell G1 empty for later additions.. actually i got the code for subtraction but i am not able to find code for addition. below is the code for subtraction.

Private Sub Worksheet_Change(ByVal Target As Range)
If Intersect(Target, Range("F7:F200")) Is Nothing Then Exit Sub
Application.EnableEvents = False
With Target
.Offset(, -2).Value = .Offset(, -2).Value - .Value
.ClearContents
End With
Application.EnableEvents = True
End Sub

 

[Peter_SSs]

Welcome to the MrExcel board!

When posting code please use code tags. My signature block below has more details.

Give this replacement code a try.

Private Sub Worksheet_Change(ByVal Target As Range)
  Dim Changed As Range, Cell As Range
  Dim Amt As Double
  
  Set Changed = Intersect(Target, Range("F1:G200"))
  If Not Changed Is Nothing Then
    Application.EnableEvents = False
    For Each Cell In Changed
      If Len(Cell.Value) > 0 Then
        Select Case Cell.Column
          Case 6: Amt = -Cell.Value
          Case 7: Amt = Cell.Value
        End Select
        Range("D" & Cell.Row).Value = Range("D" & Cell.Row).Value + Amt
        Cell.ClearContents
      End If
    Next Cell
    Application.EnableEvents = True
  End If
End Sub

 

[siddheshmumbaikar]

Thanks a lot, This has made my day. appreciate your help very much, thank you once again.

 

[Peter_SSs]

Thanks a lot, This has made my day. appreciate your help very much, thank you once again.

You're welcome. Thanks for the follow-up.