Adding CC to email sending macro

[parag54]

Hello All,

i am currently using a macro for sending some reports, but it has got only To option. i need to add cc in it.

could you please help it.


-- removed inline image ---



Code is as below:


Sub Send_Row_Or_Rows_Attachment_1()
'Working in 97-2010
Dim rng As Range
Dim Ash As Worksheet
Dim Cws As Worksheet
Dim Rcount As Long
Dim Rnum As Long
Dim FilterRange As Range
Dim FieldNum As Integer
Dim mailAddress As String
Dim NewWB As Workbook
Dim TempFilePath As String
Dim TempFileName As String
Dim FileExtStr As String
Dim FileFormatNum As Long
Dim I As Long
Dim OutApp As Object
Dim OutMail As Object
Dim strbody As String
Dim Mailsub As String
Dim Actwk As String
Dim Actwk_Temp As String

On Error GoTo cleanup

With Application
.EnableEvents = False
.ScreenUpdating = False
End With

Actwk = ActiveWorkbook.Name

'Set filter sheet, you can also use Sheets("MySheet")
Set Ash = ActiveSheet

'Set filter range and filter column (column with names)
Set FilterRange = Ash.Range("A7:W" & Ash.Rows.Count)
FieldNum = 2 'Filter column = A because the filter range start in column A

'Add a worksheet for the unique list and copy the unique list in A1
Set Cws = Worksheets.Add
FilterRange.Columns(FieldNum).AdvancedFilter Action:=xlFilterCopy, CopyToRange:=Cws.Range("A1"), CriteriaRange:="", Unique:=True

'Count of the unique values + the header cell
Rcount = Application.WorksheetFunction.CountA(Cws.Columns(1))

'If there are unique values start the loop
If Rcount >= 2 Then
For Rnum = 2 To Rcount

'Look for the mail address in the MailInfo worksheet
mailAddress = ""
On Error Resume Next
mailAddress = Application.WorksheetFunction. _
VLookup(Cws.Cells(Rnum, 1).Value, _
Worksheets("Mailinfo").Range("A1:B" & _
Worksheets("Mailinfo").Rows.Count), 2, False)
On Error GoTo 0

If mailAddress <> "" Then

'Filter the FilterRange on the FieldNum column
FilterRange.AutoFilter Field:=FieldNum, _
Criteria1:=Cws.Cells(Rnum, 1).Value

'Copy the visible data in a new workbook
With Ash.AutoFilter.Range
On Error Resume Next
Set rng = .SpecialCells(xlCellTypeVisible)
On Error GoTo 0
End With

Set NewWB = Workbooks.Add(xlWBATWorksheet)
Actwk_Temp = ActiveWorkbook.Name
rng.Copy
With NewWB.Sheets(1)
.Cells(1).PasteSpecial Paste:=8
.Cells(1).PasteSpecial Paste:=xlPasteValues
.Cells(1).PasteSpecial Paste:=xlPasteFormats
.Cells(1).Select
.Name = "OPO Report"
Application.CutCopyMode = False
End With

Workbooks(Actwk).Activate
Sheets("Process Sheet").Select
Workbooks(Actwk).Sheets("Process Sheet").Copy After:=Workbooks(Actwk_Temp).Sheets(1)

Workbooks(Actwk_Temp).Sheets("OPO Report").Select
Cells.Select
Cells.EntireColumn.AutoFit
Cells(1, 1).Select

'Create a file name
TempFilePath = Environ$("temp") & ""
TempFileName = "Open Order Report - " & Sheets("OPO Report").Range("B2") _
& ""

If Val(Application.Version) < 12 Then
'You use Excel 2000-2003
FileExtStr = ".xls": FileFormatNum = -4143
Else
'You use Excel 2007-2010
FileExtStr = ".xlsx": FileFormatNum = 51
End If


Set OutApp = CreateObject("Outlook.Application")
Set OutMail = OutApp.CreateItem(0)

strbody = "<p style='font-family:calibri;font-size:14;color:Black'>" & "Dear Valued Supplier," & "</p>" & _
"<p style='font-family:calibri;font-size:14;color:Black'>" & "Please find attached the updated PO Commit Report for your review and to fill out columns." & "</p>" & _
"<p style='font-family:calibri;font-size:14;color:Black'>" & "Please Note:" & "</p>" & _
"<p style='font-family:calibri;font-size:14;color:Black'>" & "1. we need appropriate reason on Supplier Comments." & _
"<p style='font-family:calibri;font-size:14;color:Black'>" & "2. Commit date provided earlier is mentioned in column H." & "</p>" & _
"<p style='font-family:calibri;font-size:14;color:Red'>" & "3. Need tracking details if the shipments are in-transit. Please mention the tracking# in Column W." & "</p>" & _
"<p style='font-family:calibri;font-size:14;color:Black'>" & "4. For all push-out of commit dates, please send email to notify me separately." & "</p>" & _
"<p style='font-family:calibri;font-size:14;color:Black'>" & "Thank you," & "</p>" & _
"<p style='font-family:calibri;font-size:14;color:Black'>" & "Prag" & "</p>"



Mailsub = "Open Order Report - " & Range("B2") & Format(Now, " - [$-409]d-mmm-yyyy;@")

With NewWB
.SaveAs TempFilePath & TempFileName & FileExtStr, _
FileFormat:=FileFormatNum

On Error Resume Next
With OutMail
.SentOnBehalfofName = "prag_mechen@yahoo.co.in"
'.To = ThisWorkbook.Sheets("Mailinfo").Range("mailAddress").String
.To = mailAddress
.Subject = Mailsub

.HTMLBody = strbody
.Attachments.Add NewWB.FullName

.Send

End With

On Error GoTo 0
.Close SaveChanges:=False
End With

Kill TempFilePath & TempFileName & FileExtStr


End If

'Close AutoFilter
Ash.AutoFilterMode = False

Next Rnum
End If

cleanup:
Application.DisplayAlerts = False
Cws.Delete
Application.DisplayAlerts = True

With Application
.EnableEvents = True
.ScreenUpdating = True
End With
Sheets("FilterExample").Select
End Sub

 

[burnstripe]

Hello,

To add a cc to the email all you need to do is add .cc when you are working with the outlook object. See below an extract of your code with edited content highlighted in red. You can set the .cc property anywhere after "with outmail" but before ".send". Also if you wanted you could blind copy in someone by using .bcc="copyin@yahoo.com" instead.

Edited Snippet (Added content in red)

With OutMail
.SentOnBehalfofName = "prag_mechen@yahoo.co.in"
'.To = ThisWorkbook.Sheets("Mailinfo").Range("mailAddress").String
.To = mailAddress
.Cc = "copyin@yahoo.com"
.Subject = Mailsub

.HTMLBody = strbody
.Attachments.Add NewWB.FullName

.Send

End With

Hope this helps
Thanks
Burnstripe

 

[parag54]

Thank you so much!!! it worked!