Adding Hyperlink title

[josros60]

Found code below, how to modify it that display a title instead of whole link.

.   
Sub Test()
Dim fd As FileDialog
Dim FilePicked As Integer
Dim UserRange As Range, UserCell As Range

Set fd = Application.FileDialog(msoFileDialogFilePicker)
' Change initial folder as needed or store it in a cell and reference that
fd.InitialFileName = "c:\Temp\"
fd.AllowMultiSelect = True
FilePicked = fd.Show

If FilePicked = 0 Then
    MsgBox "You hit cancel"
Else
    'Using inputbox to get selected Range
    Set UserRange = Application.InputBox(Prompt:="Please Select a Cell", Title:="Cell Select", Type:=8)
    'Get first cell of selected range
    Set UserCell = UserRange.Cells(1)
  
    'loop through selecteditems from FileDialog and create hyperlink offsetting cell by 1 column each time
    For i = 1 To fd.SelectedItems.Count
      UserCell.Hyperlinks.Add Anchor:=UserCell, Address:=fd.SelectedItems(i)
      Set UserCell = UserCell.Offset(0, 1)
    Next
End If

End Sub

Thank you

 

[Akuini]

how to modify it that display a title instead of whole link.

You mean display the filename?

 

[josros60]

Yes,

Thank you.

 

[josros60]

Yes,
Thank you.

 

[Akuini]

Try:

    'loop through selecteditems from FileDialog and create hyperlink offsetting cell by 1 column each time
    Dim ary
    For i = 1 To fd.SelectedItems.Count
    ary = Split(fd.SelectedItems(i), "\")
    UserCell.Hyperlinks.Add Anchor:=UserCell, Address:=fd.SelectedItems(i), TextToDisplay:=ary(UBound(ary))
      Set UserCell = UserCell.Offset(0, 1)
    Next