aligning a userform

[methody]

Hello
Can anyone help. I am using a userform which opens in the middle of the sheet but this is covering material which I want to be visible when the userform is being filled in. Is there a way of automatically opening on the right of the page. I'd appreciate any help
Methody

 

[Tom Urtis]

You can specify positioning at the Initialization event (when the userform is called), for example:

Private Sub UserForm_Initialize()
'Upper left
Me.StartUpPosition = 0
Dim Top As Double, Left As Double
Top = Abs(Application.Top) + (Application.Height - ActiveWindow.Height) + (Application.UsableHeight - ActiveWindow.UsableHeight)
Left = Abs(Application.Left) + ActiveWindow.Width - ActiveWindow.UsableWidth
Me.Top = Top
Me.Left = Left
End Sub


The other 3 corners would be:

'Upper right
Me.StartUpPosition = 0
Dim Top As Double, Left As Double
Top = Abs(Application.Top) + (Application.Height - ActiveWindow.Height) + (Application.UsableHeight - ActiveWindow.UsableHeight)
Left = Abs(Application.Left) + (Application.Width) - (Me.Width + 10)
Me.Top = Top
Me.Left = Left

'Lower left
Me.StartUpPosition = 0
Dim Top As Double, Left As Double
Top = Abs(Application.Top) + (Application.Height) - (Me.Height + 10)
Left = Abs(Application.Left) + ActiveWindow.Width - ActiveWindow.UsableWidth
Me.Top = Top
Me.Left = Left

'Lower right
Me.StartUpPosition = 0
Dim Top As Double, Left As Double
Top = Abs(Application.Top) + (Application.Height) - (Me.Height + 10)
Left = Abs(Application.Left) + (Application.Width) - (Me.Width + 10)
Me.Top = Top
Me.Left = Left

 

[Whisperer14]

Or you can set it manually by trial and error to any position on the screen.

In the properties for the Userform select the 'StartUpPosition' to 0-Manual,
then select the 'Left' to say 50 and the 'Top' to 200, experiment until you are happy with the position

HTH

Gordon

 

[methody]

thank you both

 

[Tom Urtis]

Or you can set it manually by trial and error to any position on the screen.

That would only be a practical approach if you are the only one using the program and your screen resolution setting never changes. If you ever change your resolution, or other users use the program whose screen settings are (inevitably) different than yours, that manual setting approach would not fit the other screens.

Easier to just "set it and forget it" in code.

 

[Whisperer14]

Quite agree Tom,

so how about modifying your excellent code to give a position which is 50 inset from the right side of the page and in the middle of the useable height, taking into account the height and width of the userform.

Gordon

 

[Tom Urtis]

Try this:

Private Sub UserForm_Initialize()
Me.StartUpPosition = 0
Me.Top = (Application.Height - Me.Height) / 2
Me.Left = (Application.Width - Me.Width - 50)
End Sub

 

[Whisperer14]

Thanks Tom,

I got lost trying to manipulate your earlier post - LOL

Gordon