Array not passing to function

[trough]

I believe I have an array function IF statement that returns an array that I then try to pass to a user function to perform further processing of the data before returning to the workbook with the final array answer. However, it appears as though the user function isn't even getting ran. I set a break at the Redim line and it's never seen. It's like nothing is happening. I don't normally work with ranges or the passing of arrays so I've been researching but I am not having any luck. Could someone please tell me if I'm passing the data into and out of the function properly? Column H shows the result I desire in column E where the function is being used.


Excel 2010

	A	B	C	D	E	F	G	H
1	Name	User	Active		UserList
2	Smith, John	JSmith	No		#VALUE!		-	JDoe
3	Doe, John	JDoe	Yes		#VALUE!		JDoe	TCarver
4	Jones, Mary	MJones	No		#VALUE!		-	-
5	,	SLincoln	No		#VALUE!		-	-
6	Carver, Tim	TCarver	Yes		#VALUE!		TCarver	-
7							|	|
8						Result of IF statement	____________|	|
9								|
10							Desired result of UserList function	__|

<tbody>
</tbody>

Sheet1​

Array Formulas Cell Formula E2:E6 {=UserList(IF(A2:A6=", ","-",IF(C2:C6="No","-",B2:B6)))} G2:G6 {=IF(A2:A6=", ","-",IF(C2:C6="No","-",B2:B6))} <tbody> </tbody> Entered with Ctrl+Shift+Enter. If entered correctly, Excel will surround with curly braces {}. Note: Do not try and enter the {} manually yourself

<tbody>
</tbody>

Option Explicit
Option Base 1


Function UserList(UName() As String)

' declare variables
Dim MyList() As String
Dim nList As Long
Dim i As Long
Dim j As Long

' get list size and dimension dynamic variable
nList = UBound(UName)
ReDim MyList(nList)

' populate dynamic list with names
j = 0
For i = 1 To nList
 If UName(i) <> "-" Then
  j = j + 1
  MyList(j) = UName(i)
 End If
Next i

' populate empty variable positions
If j < nList Then
 For i = j + 1 To nList
  MyList(i) = "-"
 Next i
End If

' write back to workbook
UserList = MyList()

End Function

 

[VBA Geek]

try to make these changes

Function UserList([B]UName As Variant[/B]) 

' declare variables
Dim MyList() As String
Dim nList As Long
Dim i As Long
Dim j As Long

' get list size and dimension dynamic variable
nList = UBound(UName)
[B]ReDim MyList(1 To nList)[/B]

' populate dynamic list with names
j = 0
For i = 1 To nList
 If UName(i[B], 1[/B]) <> "-" Then
  j = j + 1
  MyList(j) = UName(i[B],[/B] [B]1[/B])
 End If
Next i

' populate empty variable positions
If j < nList Then
 For i = j + 1 To nList
  MyList(i) = "-"
 Next i
End If

' write back to workbook
UserList = MyList()

End Function

 

[RoryA]

Isn't this the same question you posted here?

 

[trough]

It works now except I had to change the last line to:

UserList = Application.Transpose(MyList)

This is interesting because I had read that when passing arrays the type had match exactly what the data type actually was (in this case String) and that I couldn't use variant. I had tried Variant before but missed treating it as a 2-dimensional array.

Thank you.