Array variable declaration question

[andydtaylor]

Hi,

Please could someone tell me why the below code to pick up array values from worksheet doesn't work if 'thisarray' is decaired as double? My values were (9,8,7;6,5,4;3,2,1)

I suspect I'm about to learn something fundamental!


Thanks,


Andy

Sub test3()
Dim thisarray As Variant

thisarray = Selection.Value

Stop

End Sub

 

[RoryA]

Selection.Value returns an array of type variant. You can therefore only assign it directly to a Variant or to a dynamic array of type variant. To assign the values to an array of type Double you would have to size the array and then loop through the cells assigning the values to the array.
HTH

 

[andydtaylor]

Hi Rory,

I made it this far:

Option Base 1

Sub test4()
 Dim length As String
 Dim width As String
 Dim input_array() As Double
 
    length = Selection.Rows.Count
    width = Selection.Columns.Count

ReDim input_array(length, width)

    Stop
End Sub

With regard to filling the array I found the below but this hard codes an assumtion about the columns filled. Can you suggest a flexible apporach I feel like I'm nearly there but can't quite get my head around it. Would the offset function be used here?

Dim arrData (1 to 7, 1 to 2)
Dim i As Integer
For i = 1 to 7
   ' Values from column A fill the first series of the
   ' array. If these values are strings, they become
   ' the labels for the rows.
   arrData(i, 1) = wkbObj.Worksheets(1) _
   .Range("A" & i + 1).Value

   ' Then values from column B fill the second.
   arrData(i, 2) = wkbObj.Worksheets(1) _
   .Range("B" & i + 1).Value
Next i

Thanks,


Andrew

 

[RoryA]

Sure - something like this:

Sub test4()
 Dim length As Long
 Dim width As Long
Dim x as long, y as long
 Dim input_array() As Double
 
    length = Selection.Rows.Count
    width = Selection.Columns.Count

ReDim input_array(1 to length, 1 to width)
for x = 1 to length
    for y = 1 to width
        input_array(x, y) = Selection.Cells(x, y).Value
    next y
next x
    Stop
End Sub