Assigning a VBA to a specific column.

[JEH105]

Hi everyone,

I'm not very experienced in VBA, but I found the following code in order to add time stamps to a workbook. However, I need the timestamps to be added to column D only. Currently, it applies the timestamps to ALL cells. Here is the code:

Private Sub Worksheet_Change(ByVal Target As Range)

With Target

If Not IsEmpty(.Value) Then

' Jack Clears the comment.

.ClearComments

' Jack Creates the comment.

.AddComment (Application.UserName & " ; " & Date & " ;" & Time)

' Can have user name in top left by adding name between ""

.Comment.Visible = False



Else: .ClearComments

End If

End With



End Sub

I appreciate any help you can provide!

 

[Rick Rothstein]

Give this Change event code a try...

Private Sub Worksheet_Change(ByVal Target As Range)
  Dim Cell As Range
  On Error GoTo NothingInColumnD
  For Each Cell In Intersect(Target, Columns("D"))
    With Cell
      If .Column = 4 Then
        .ClearComments
        If Len(.Value) Then
          .AddComment Application.UserName & " ; " & Date & " ;" & Time
          .Comment.Visible = False
        End If
      End If
    End With
  Next
NothingInColumnD:
End Sub

 

[JEH105]

Thank you so much! This is exactly what I needed. I appreciate your help at this time!