Automating password access to web pages with VBA

[RustB]

Hello
I've had success accessing some user / password protected web sites with the following code but this website has got me scratching my head. I'm sure its an old problem but I can't find an existing forum conversation that helps. I got the element names from the webpage source code and wondering what I'm doing wrong.

Can anyone help please?

Many thanks in advance

Sub pwsite()
Set ie = CreateObject("InternetExplorer.Application")
With ie
.Visible = True
.Navigate "https://www.bloodhound.net.au/"
Do Until .ReadyState = 4
DoEvents
Loop

ie.Document.all("user_id").Value = "uuuuuuuu"
ie.Document.all("password").Value = "ppppppppp"
ie.Document.all("login").Click
End With
End Sub

 

[Ombir]

Set Reference to Microsoft HTML object library and Microsoft Internet Controls before running below code:

Sub Ombir_09Dec2016()
Dim ie      As InternetExplorer
Dim doc     As HTMLDocument

Set ie = New InternetExplorer

With ie
    .Navigate "https://www.bloodhound.net.au/"
    .Visible = True
    Do While .ReadyState <> 4: DoEvents: Loop

    Set doc = .Document.getElementsByTagName("iframe")(0).contentDocument
   
    With doc
        .getElementsByName("user_id")(0).Value = "Rust"
        .getElementsByName("password")(0).Value = "RustBPassword"
        .getElementsByName("login")(0).Click
    End With
End With
ie.Quit
End Sub

 

[RustB]

Many Thanks Ombir ... Awesome
I tried your code and at first it rejected the dim and set internet explorer lines but when I modified those it worked perfectly.
Here's what I ended up with. I also left the quit off the end also because I need to carry on and extend the code to do stuff on the page I sign onto.
This is my first time on the forum and I'm so impressed. Thanks again!!

Set ie = CreateObject("InternetExplorer.Application")
<strike>Dim ie As InternetExplorer</strike>
Dim doc As HTMLDocument

<strike>Set ie = New InternetExplorer</strike>

With ie
.Navigate "https://www.bloodhound.net.au/"
.Visible = True
Do While .ReadyState <> 4: DoEvents: Loop

Set doc = .Document.getElementsByTagName("iframe")(0).contentDocument

With doc
.getElementsByName("user_id")(0).Value = "UUUUUU"
.getElementsByName("password")(0).Value = "PPPPPP"
.getElementsByName("login")(0).Click
End With
End With

 

[Ombir]

Many Thanks Ombir ... Awesome
I tried your code and at first it rejected the dim and set internet explorer lines but when I modified those it worked perfectly.
End With

You didn't read my my first line carefully in post 2. I used the early binding. So you have to set references to these libraries from VBE Editor----->>Tools----->References

 

[RustB]

Yes Sorry Ombir, I set the reference to HTML object Library but not the Microsoft Internet Controls as you point out.
I just did that and now it works exactly as you intended.
Thanks Again that is really great.
Regards
RustB