Automating 'save to PDF' directly to Downloads & Email

[aspiringnerd]

Sub EmailInspection()
Dim xSht As Worksheet
'Dim xFileDlg As FileDialog
Dim xFolder As String
Dim xYesorNo As Integer
Dim xOutlookObj As Object
Dim xEmailObj As Object
Dim xUsedRng As Range

Set xSht = ActiveSheet

xFolder = Environ("HOMEDRIVE") & Environ("HOMEPATH") & "\Downloads" + "\" + xSht.Range("d5").Value + " " + xSht.Range("d6").Value + " " + xSht.Name + " " + xSht.Range("d8").Value + " " + xSht.Range("d9").Value + ".pdf"

'Check if file already exist
If Len(Dir(xFolder)) > 0 Then
    xYesorNo = MsgBox(xFolder & " already exists." & vbCrLf & vbCrLf & "Do you want to overwrite it?", _
                      vbYesNo + vbQuestion, "File Exists")
    On Error Resume Next
    If xYesorNo = vbYes Then
        Kill xFolder
    Else
        MsgBox "if you don't overwrite the existing PDF, I can't continue." _
                    & vbCrLf & vbCrLf & "Press OK to exit this macro.", vbCritical, "Exiting Macro"
        Exit Sub
    End If
    If Err.Number <> 0 Then
        MsgBox "Unable to delete existing file.  Please make sure the file is not open or write protected." _
                    & vbCrLf & vbCrLf & "Press OK to exit this macro.", vbCritical, "Unable to Delete File"
        Exit Sub
    End If
End If

Set xUsedRng = xSht.UsedRange
If Application.WorksheetFunction.CountA(xUsedRng.Cells) <> 0 Then
    'Save as PDF file
    'xSht.ExportAsFixedFormat Type:=xlTypePDF, Filename:=xFolder, Quality:=xlQualityStandard
    Range("a1", "g46").ExportAsFixedFormat Type:=xlTypePDF, Filename:=xFolder, Quality:=xlQualityStandard
    
    'Create Outlook email
    Set xOutlookObj = CreateObject("Outlook.Application")
    Set xEmailObj = xOutlookObj.CreateItem(0)
    With xEmailObj
        .Display
        .To = ""
        .CC = ""
        .Subject = "Report"
        .Body = "Hello, please see attached."
        .Attachments.Add xFolder
        If DisplayEmail = False Then
            '.Send
        End If
    End With
Else
  MsgBox "The active worksheet cannot be blank"
  Exit Sub
End If
End Sub

 

[aspiringnerd]

My goal is to automatically save to Downloads, the directory isn't fixed since multiple users will be using the macro. This was my attempt at forcing the save location but I get an error 13

 

[Domenic]

It looks like one or more values from the target cells contains a number. In any case, you should use an ampersand ( & ) to concatenate . . .

xFolder = Environ("HOMEDRIVE") & Environ("HOMEPATH") & "\Downloads" & "\" & xSht.Range("d5").Value & " " & xSht.Range("d6").Value & " " & xSht.Name & " " & xSht.Range("d8").Value & " " & xSht.Range("d9").Value & ".pdf"

Hope this helps!