before double click vba help

[Sarah_Lou0607]

Hi,

I have the below code currently to hyperlink to a hidden page. This works at the moment but I'm not sure how to add in another link?

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
If ActiveCell.Address = "$I$6" Then
Worksheets("inc Priorities").Visible = True
Worksheets("inc Priorities").Activate
Else
'do nothing

End If
End Sub

 

[Fluff]

Hi & welcome to MrExcel.
How about

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
   Select Case Target.Address(0, 0)
      Case "I6"
         With Worksheets("inc Priorities")
            .Visible = xlSheetVisible
            .Activate
         End With
      Case "I7"
         With Worksheets("Main")
            .Visible = xlSheetVisible
            .Activate
         End With
   End Select
End Sub

 

[Sarah_Lou0607]

perfect thank you! also need code so that once I get back to the main sheet, it rehides those sheets again?

 

[Fluff]

You could put something like his on those sheets

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
   If Target.Address(0, 0) = "A1" Then
      Sheets("Main").Activate
      Me.Visible = xlSheetHidden
   End If
End Sub

 

[Sarah_Lou0607]

Sorry very much a beginner so a lot of this is way over my head (Any tips on how to learn welcome, as I'd love to but don't know where to start!)

I have shapes as buttons on the sheets to Return to main page so don't think the beforedoubleclick would apply here (sorry to jump to another type!)
I have macros assigned to the shapes with vba code to take me to relevant pages.

So once the macro shape takes me to the main page, I'm wondering how I get it to hide all sheets except for Main.

Hope that makes sense! Reallyyy appreciate your help!

 

[Fluff]

How about

Sub SarahLou()
   Dim Ws As Worksheet
   
   For Each Ws In Worksheets
      If Ws.Name <> "Main" Then Ws.Visible = xlSheetHidden
   Next Ws
End Sub