Bolding from 1st character up to :

[seekyourway]

Hi,

I wanted to bold all the characters in a range from the beginning up to where the ":" is. Sample files:

dsjakgjdkfa: dgda. (50%)

geadfdafd: fdagad, (.)

gadfdgad: gdadg @gdad

Data is always in 1st column. I have some code below, but when I run it, it bolds the whole thing, bypassing what's in the loop. Would someone please give an advice/pointer?

Sub Bolder2()
Dim rng As Range, r As Range, strR As String
Dim i As Long, j As Long, k As Long
Set rng = Intersect(Columns(1), ActiveSheet.UsedRange)
For Each r In rng
strR = r.Text

For i = 1 To InStr(strR, ":")
r.Font.Bold = True
Next i
Next r
End Sub

Thank you for your assistance

 

[kennypete]

This will work to do that. You need to ensure that only the characters are being emboldened, which requires your code to specify Characters within the Cell only:

Sub colourUpToColonColumnA()
    Dim lngLoop As Long
    Dim lngLastRow As Long
    Dim intPos As Integer
    lngLastRow = ActiveSheet.Cells(ActiveSheet.Rows.Count, 1).End(xlUp).Row
    For lngLoop = 1 To lngLastRow
        intPos = InStr(Cells(lngLoop, 1), ":")
        If intPos > 0 Then
            Cells(lngLoop, 1).Characters(Start:=1, Length:=intPos).Font.Bold = True
        End If
    Next lngLoop
End Sub

Or using your code as a base:

Sub Bolder2()
    Dim rng As Range, r As Range, strR As String
    Dim i As Long, j As Long, k As Long
    Set rng = Intersect(Columns(1), ActiveSheet.UsedRange)
    For Each r In rng
    strR = r.Text
        For i = 1 To InStr(strR, ":")
            r.Characters(Start:=1, Length:=i).Font.Bold = True
        Next i
    Next r
End Sub

PS: You should also ensure your profile shows what version(s) and platform(s) you are using otherwise posters may waste their time and work on solutions that you are unable to use.

 

[Peter_SSs]

S: You should also ensure your profile shows what version(s) and platform(s) you are using otherwise posters may waste their time and work on solutions that you are unable to use.

I agree.

FWIW, the default starting position for 'Characters' is 1 so this would be sufficient in either code

_ _.Characters(Length:=i).Font.Bold = True