Boolean logic using inch symbol

[nmounir]

I am trying to write a formula using the filter function that includes Boolean logic involving the inch symbol.

=Filter($A$2:$A$4058,$C$2:$C$4058=8 1/2")

8 1/2" here means 8 1/2 inch. All the data input is using 8 1/2". I tried 8 1/2""" and many others ways but nothing is working.

your help is greatly appreciated.
Cheers,
nmounir

 

[JGordon11]

Date and time field.xlsx
	A	B	C	D	E	F
1	8 1/2"	1		8 1/2"	1
2	A	2		8 1/2"	3
3	8 1/2"	3		8 1/2"	5
4	A	4		8 1/2"	7
5	8 1/2"	5
6	A	6
7	8 1/2"	7
8	A	8
9
Sheet2

Cell Formulas
Range	Formula
D1:E4	D1	=FILTER(A1:B8,A1:A8="8 1/2""")
Dynamic array formulas.

 

[nmounir]

Thank you very much JGordon11
The last thing I forgot to mention in my original question is how to add an asterisk into the formula because some are written 8 1/2" APP for example.

I tried this but didn't work
=Filter(A1:B8,A1:A8="8 1/2""*") but didn't work. I tried putting in several other places without success.

Your help is much appreciated

 

[JGordon11]

Date and time field.xlsx
	A	B	C	D	E	F	G	H	I
1	8 1/2" abc	1		8 1/2" abc	1		Filter by:	8 1/2"
2	A	2		8 1/2" defg	3
3	8 1/2" defg	3		8 1/2" hijkl	5		8 1/2" abc	1
4	A	4		8 1/2" mnopq	7		8 1/2" defg	3
5	8 1/2" hijkl	5					8 1/2" hijkl	5
6	A	6					8 1/2" mnopq	7
7	8 1/2" mnopq	7
8	A	8
9
Sheet2

Cell Formulas
Range	Formula
D1:E4	D1	=LET(m,"8 1/2""",FILTER(A1:B8,LEFT(A1:A8,LEN(m))=m))
G3:H6	G3	=LET(m,H1,FILTER(A1:B8,LEFT(A1:A8,LEN(m))=m))
Dynamic array formulas.

 

[nmounir]

Date and time field.xlsx
	A	B	C	D	E	F	G	H	I
1	8 1/2" abc	1		8 1/2" abc	1		Filter by:	8 1/2"
2	A	2		8 1/2" defg	3
3	8 1/2" defg	3		8 1/2" hijkl	5		8 1/2" abc	1
4	A	4		8 1/2" mnopq	7		8 1/2" defg	3
5	8 1/2" hijkl	5					8 1/2" hijkl	5
6	A	6					8 1/2" mnopq	7
7	8 1/2" mnopq	7
8	A	8
9
Sheet2

Cell Formulas
Range	Formula
D1:E4	D1	=LET(m,"8 1/2""",FILTER(A1:B8,LEFT(A1:A8,LEN(m))=m))
G3:H6	G3	=LET(m,H1,FILTER(A1:B8,LEFT(A1:A8,LEN(m))=m))
Dynamic array formulas.

Absolutely amazing. You are brilliant thank you very much

 

[Peter_SSs]

Not sure which formula structure you ended up using but if it is the column G:H one then I would suggest there is not really an advantage in introducing the variable m since H1 is effectively that variable anyway and using that would eliminate the need for the LET function.

21 10 05.xlsm
	A	B	C				G	H
1	8 1/2" abc	1					Filter by:	8 1/2"
2	A	2
3	8 1/2" defg	3					8 1/2" abc	1
4	A	4					8 1/2" defg	3
5	8 1/2" hijkl	5					8 1/2" hijkl	5
6	A	6					8 1/2" mnopq	7
7	8 1/2" mnopq	7
8	A	8
Filter Inch

Cell Formulas
Range	Formula
G3:H6	G3	=FILTER(A1:B8,LEFT(A1:A8,LEN(H1))=H1)
Dynamic array formulas.