Bullet Points

[longytravel]

Guys,

i have the following code
this put a allows me to produce a bullet point when i start typing in the text box

I cant however get it to prodcue more than 'one bullet' i.e more than one line of text

Any way i can get more than one bullet into a text box?

i guess i would expect another bullet to appear when i hit return

Thanks as ever!

Private Sub TextBox1_Change()
Dim MyArray() As String
MyArray = Split(TextBox1.Text, vbCrLf)
For i = LBound(MyArray) To UBound(MyArray)
If Left(Trim(MyArray(i)), 1) <> "•" Then _
MyArray(i) = "• " & MyArray(i)
If i = 0 Then
TextBox1.Text = MyArray(i)
Else
TextBox1.Text = TextBox1.Text & vbCrLf & MyArray(i)
End If
Next i
End Sub

 

[Jerry Sullivan]

Try moving your code to the TextBox1_KeyUp event and modifying it to read....

Private Sub TextBox1_KeyUp(ByVal KeyCode As MSForms.ReturnInteger, _
    ByVal Shift As Integer)
    Dim MyArray() As String
    Dim i As Long

    If KeyCode = 13 Then
        MyArray = Split(TextBox1.Text, vbCrLf)
        For i = LBound(MyArray) To UBound(MyArray)
            If Left(Trim(MyArray(i)), 1) <> "•" Then _
                MyArray(i) = "• " & MyArray(i)
                If i = 0 Then
                    TextBox1.Text = MyArray(i)
                Else
                TextBox1.Text = TextBox1.Text & vbCrLf & MyArray(i)
            End If
        Next i
    End If
End Sub

If you want the first line bullet to appear when you click or tab into the textbox
and be removed if the textbox is otherwise blank add....

Private Sub TextBox1_Enter()
    If Len(TextBox1.Text) = 0 Then
        TextBox1.Text = "• "
    End If
End Sub

Private Sub TextBox1_Exit(ByVal Cancel As MSForms.ReturnBoolean)
    If TextBox1.Text = "• " Then
        TextBox1.Text = ""
    End If
End Sub

To work as you describe, these TextBox1 properties should be set as folllows:
(set in the Properties window at design time or in UserForm1_Initialize)

TextBox1.EnterKeyBehavior = True
TextBox1.MultiLine = True

 

[longytravel]

Truly impressive!
Works like a dream - thank you!