Button ForeColor switches from black to blue when click on.

[TAPS_MikeDion]

Hi all,
I did a search on here, but didn't find what I'm looking for.

I currently have 16 (which may go up to ???) command buttons on a form, and I wish to have the forecolor change from black to blue (&H00FF0000&) when the user clicks on any given button. I was trying to avoid using 16 sets (or more) of .ForeColor commands per command button Sub to set all buttons to black except for the one clicked.

In a nut shell, all buttons would have their forecolor set to black, and only the clicked-on button forecolor switches to blue.

Thanks to anyone that can help!

-Mike

 

[pgc01]

Hi Mike

You can define a new class for the buttons in this group of commandbuttons.

This is an example. Do the following test:

1 - create a new userform and insert some commandbuttons and other controls

2 - in some of the commandbuttons set the Tag property to "CButton"

3 - paste in the userform module:

Option Explicit
 
Private CButtonsColl As New Collection
Private CButtonLastClickedP As clsCButton
 
Private Sub UserForm_Initialize()
Dim cbutton As clsCButton
Dim ctrl As MSForms.Control
 
For Each ctrl In Me.Controls
    If TypeOf ctrl Is MSForms.CommandButton Then
        If ctrl.Tag = "CButton" Then
            Set cbutton = New clsCButton
            Set cbutton.CButtonObj = ctrl
            CButtonsColl.Add cbutton
        End If
    End If
Next ctrl
End Sub
 
Property Set CButtonLastClicked(cButtonLastClickedNew As clsCButton)
Set CButtonLastClickedP = cButtonLastClickedNew
End Property
 
Property Get CButtonLastClicked() As clsCButton
Set CButtonLastClicked = CButtonLastClickedP
End Property

4 - insert a new class module and change its name to "clsCButton"

5 - paste in the clsCButton class module

Option Explicit
 
Private WithEvents CButtonP As MSForms.CommandButton
 
Property Set CButtonObj(ctrlCButton As MSForms.CommandButton)
Set CButtonP = ctrlCButton
End Property
 
Property Let ForeColor(ForeColorNew)
CButtonP.ForeColor = ForeColorNew
End Property
 
Private Sub CButtonP_Click()
Dim cbutton As clsCButton
 
Set cbutton = UserForm1.CButtonLastClicked
If Not cbutton Is Nothing Then cbutton.ForeColor = &H80000012
CButtonP.ForeColor = &HFF0000
Set UserForm1.CButtonLastClicked = Me
End Sub

6 - Test this solution. Execute the userform and check that for all the buttons that you set the tag to CButton you get the behaviour you want: when you click on one of these buttons its forecolour becomes blue and the forecolor of the previous button clicked gets black again.

 

[TAPS_MikeDion]

Thanks PGC,

I'll give it a shot!

-Mike

 

[TAPS_MikeDion]

S W E E T !!!


After making the minor changes needed to fit into my code, it works perfectly!

Thanks a lot, I really appreciate it.

-Mike

 

[pgc01]

I'm glad it helped. Using a class usually simplifies this type of problems, where you want a group of objects to have the same behaviour.

 

[tuiajdf]

S W E E T !!!


After making the minor changes needed to fit into my code, it works perfectly!

Thanks a lot, I really appreciate it.

-Mike

I accept with information : it works perfectly!