# Button of 0 and 1

#### andrichara

##### New Member
hi guys i would like to make a 2 buttons.The one will result 0 and the other one 1 at A7:A47.so when i press the zero button for examplle will result a zero at A7,then when i press again any of both will result at A8..then A9 and so on.can you help me on that?thank you!

### Excel Facts

Move date out one month or year
Use =EDATE(A2,1) for one month later. Use EDATE(A2,12) for one year later.

#### Joe4

Assuming that you have nothing in column A below row 47, here are the two prcoedures you need:
Code:
``````Sub ZeroButton()

Dim r As Long

'   Find next row to populate
r = Cells(Rows.Count, "A").End(xlUp).Row + 1

'   Verify row selection
If r < 7 Then
r = 7
Else
If r > 47 Then
MsgBox "Cell A47 already populated", vbOKOnly
Exit Sub
End If
End If

'   Populate cell
Cells(r, "A") = 0

End Sub

Sub OneButton()

Dim r As Long

'   Find next row to populate
r = Cells(Rows.Count, "A").End(xlUp).Row + 1

'   Verify row selection
If r < 7 Then
r = 7
Else
If r > 47 Then
MsgBox "Cell A47 already populated", vbOKOnly
Exit Sub
End If
End If

'   Populate cell
Cells(r, "A") = 1

End Sub``````
After adding the code, then just add a few command buttons and add this VBA code to each one.

#### DanteAmor

##### Well-known Member
Another option:

Code:
``````Sub Button1()
Call FillValue(1)
End Sub
Sub Button2()
Call FillValue(0)
End Sub
Sub FillValue(n As Long)
Dim i As Long
For i = 7 To 47
If Cells(i, "A").Value = "" Then
Cells(i, "A").Value = n
Exit For
End If
Next
If i = 48 Then MsgBox "No cells available"
End Sub``````

#### Joe4

Nice one Dante!

I knew there had to be a way to avoid duplicating very similar code, and overlooked the obvious (a single procedure with parameters!)