Calculate federal withholding rates from tax table?

[charlesstricklin]

I'd like to calculate the amount of withholding for the federal taxes based on the current IRS rates. I could use a nested IF statement, but I'd prefer something using the actual table provided by the IRS, making it easier to update when the new tax codes come out.

To wit, the single, biweekly withholding table:

	A	B	C
1	Amount	Base	Percent
2	$96.00	-	10%
3	$480.00	$38.40	15%
4	$1,656.00	$214.80	25%
5	$3,877.00	$770.05	28%
6	$7,983.00	$1,919.73	33%
7	$17,242.00	$7,975.20	35%
8	$17,313.00	$5,000.05	40%

<tbody>
</tbody>

So, if a person's biweekly gross income is $2,000.00, they'd be taxed based on line 4:

$214.80 + (25% * ($2,000.00 - $1,656.00))

$214.80 + (25% * $344.00)

$214.80 + (25% * $344.00)

$214.80 + $86

$300.80

So, they'd be taxes $330.80 on a biweekly gross income of $2,000.00

If there a calculation to handle this table data?

 

[joeu2004]

To wit, the single, biweekly withholding table:
[....]
So, if a person's biweekly gross income is $2,000.00, [....] they'd be taxes $330.80 on a biweekly gross income of $2,000.00[.] If there a calculation to handle this table data?

I have not vetted your withholding table. But add column D with formulas shown to the right.

	A​	B​	C​	D​
1	Amount​	Base​	Percent​	%Diff​
2	$96.00	-	10%	10.00%	D2: =C2
3	$480.00	$38.40	15%	5.00%	D3: =C3-C2
4	$1,656.00	$214.80	25%	10.00%
5	$3,877.00	$770.05	28%	3.00%
6	$7,983.00	$1,919.73	33%	5.00%
7	$17,242.00	$7,975.20	35%	2.00%
8	$17,313.00	$5,000.05	40%	5.00%

<TBODY>
</TBODY>

Copy D3 down through D8.

Then if the taxable income is in G1 (2000), the following formula calculates the withholding tax (300.80):

=SUMPRODUCT((G1>$A$2:$A$8)*(G1-$A$2:$A$8),$D$2:$D$8)

 

[joeu2004]

I have not vetted your withholding table.

FYI, the table you posted, and I copied and embellished, is the US 2015 withholding table for Single Semimonthly (Table 3), not Biweekly (Table 2). (Click here.)

 

[petertenthije]

For this calculation I am using your table above ($A$1:$C$8). For the income you want to know the taxes for I am using cell F2.

Here is the full formula:
=INDEX($B:$B;MATCH($F2;$A$1:$A$8;1);1)+($F2-INDEX($A$1:$A$8;MATCH($F2;$A$1:$A$8;1);1))*INDEX($C:$C;MATCH($F2;$A$1:$A$8;1);1)



Here is a breakdown of the individual steps:

This step looks up the base value (214,80$)
=INDEX($B$1:$B$8;MATCH($F2;$A$8:$A$8;1);1)

This step is used to calculate the percentage value (25%)
=INDEX($C$1:$C$8;MATCH($F2;$A$1:$A$8;1);1)

This step is used to calculate the dollars ($2000-$1656 = $344)
=($F2-INDEX($A$1:$A$8;MATCH($F2;$A$1:$A$8;1);1))



One minor but important caveat, with your table this formula will only work for incomes of 96 dollar and higher. If the income is less the 96 dollar then the formula won't work. To counter that you should add a row between the header and the first row with data. In this row you have to just type 0 for each cell. Of course it is highly unlikely for someone to have an income lower then 96$, so in real life this issue is not likely to occur.

 

[charlesstricklin]

FYI, the table you posted, and I copied and embellished, is the US 2015 withholding table for Single Semimonthly (Table 3), not Biweekly (Table 2). (Click here.)

Yes, I believe you're correct. Sorry for the mistake.Here's the correct table, taken directly from the IRS:

Also, can anyone explain what that last column represents?

Given that information, would you agree that this would be the best way of representing that table as a lookup table?

	A	B	C
1	Wages	Percentage	Tax
2	$88.00	10%	$0
3	$443.00	15%	$35.50
4	$1,529.00	25%	$198.40
5	$3,579.00	28%	$710.90
6	$7,369.00	33%	$1,772.10
7	$15,915.00	35%	$4,592.28
8	$15,981.00	39.%	$4,615.38

<tbody>
</tbody>

 

[joeu2004]

Here's the correct table, taken directly from the IRS [...]. Also, can anyone explain what that last column represents?

Your problem in understanding might be because "of excess over" is in the wrong place. This is what I find in IRS Pub 15 (HTML version; click here, then page down).

So it behaves exactly as you described in your original posting, correcting the numbers. For taxable wages of $2000, the tax is: 198.40 plus 25% of (2000 - 1529); that is, 25% "of excess over" 1529.

But note that the right-most column ("of excess over") is and always will be identical to the left-most column (taxable wages).

So only one column is not needed in an Excel implementation. It is best to retain the left-most column for look-up purposes.

Given that information, would you agree that this would be the best way of representing that table as a lookup table?

The table can be:

	A​	B​	C​	D​
1	Taxl Wages Over</SPAN>	Base Tax</SPAN>	Plus</SPAN>	Diff%</SPAN>
2	$0.00</SPAN>	$0.00</SPAN>	0.00%</SPAN>	0.00%</SPAN>
3	$88.00</SPAN>	$0.00</SPAN>	10.00%</SPAN>	10.00%</SPAN>
4	$443.00</SPAN>	$35.50</SPAN>	15.00%</SPAN>	5.00%</SPAN>
5	$1,529.00</SPAN>	$198.40</SPAN>	25.00%</SPAN>	10.00%</SPAN>
6	$3,579.00</SPAN>	$710.90</SPAN>	28.00%</SPAN>	3.00%</SPAN>
7	$7,369.00</SPAN>	$1,772.10</SPAN>	33.00%</SPAN>	5.00%</SPAN>
8	$15,915.00</SPAN>	$4,592.28</SPAN>	35.00%</SPAN>	2.00%</SPAN>
9	$15,981.00</SPAN>	$4,615.38</SPAN>	39.60%</SPAN>	4.60%</SPAN>

<TBODY>
</TBODY>

With taxable wages in G1 ($2000), the tax can be calculated using:

=ROUND(SUMPRODUCT((G1>$A$2:$A$9)*(G1-$A$2:$A$9),$D$2:$D$9), 2)

Note that B1:B9 (column B) is not needed. Also, A2:D2 (row 2) is not needed in this case because the tax is zero.

Also note that I add explicit rounding, which is a good idea when you want a dollars-and-cents result.

D2 is =C2, and D3 is =C3-C2. Copy D3 down through D9.

(If you omit row 2, D3 is =C3, and D4 is =C4-C3.)

-----

If you prefer petertenthije's approach, the tax can be calculated using:

=ROUND(VLOOKUP(G1,$A$2:$C$9,2) + VLOOKUP(G1,$A$2:$C$9,3)*(G1-VLOOKUP(G1,$A$2:$C$9,1)), 2)

Note that row 2 and column B are required for that formula, unlike the SUMPRODUCT formula above.

But note the D1:D9 (column D) is not needed.

-----

In either case, note that the left-most column is taxable wages.

Usually, that is not the same as gross wages, which you wrote in your original posting.

At a minimum, usually a withholding "allowance" is subtracted from gross wages.

In addition, other nontaxable amounts are also subtracted; for example, employee contribution to a
401(k).

The withholding "allowance" is determined by multiplying the number of allowances specified in the
W-4 form by the amount indicated in the following table. Usually, the number of allowances is at least 1, although it can be zero.

So if $2000 is truly gross wages, taxable wages (G1) is typically $1846.20 (2000 - 153.80).

This is not a tax advice forum. Refer to IRS Pub 15 for details.

 

[charlesstricklin]

Here is the full formula:
=INDEX($B:$B;MATCH($F2;$A$1:$A$8;1);1)+($F2-INDEX($A$1:$A$8;MATCH($F2;$A$1:$A$8;1);1))*INDEX($C:$C;MATCH($F2;$A$1:$A$8;1);1)

Here is a breakdown of the individual steps:

This step looks up the base value (214,80$)
=INDEX($B$1:$B$8;MATCH($F2;$A$8:$A$8;1);1)

This step is used to calculate the percentage value (25%)
=INDEX($C$1:$C$8;MATCH($F2;$A$1:$A$8;1);1)

This step is used to calculate the dollars ($2000-$1656 = $344)
=($F2-INDEX($A$1:$A$8;MATCH($F2;$A$1:$A$8;1);1))

Excel complains of a problem with each formula. I think something's wrong with the INDEX function. I've tried changing the array from $B:$B to B1:B8, but no luck.

 

[charlesstricklin]

Excel complains of a problem with each formula. I think something's wrong with the INDEX function. I've tried changing the array from $B:$B to B1:B8, but no luck.

I figured out why. The first array should be $B1:$B8, not $B:$B. Second, the semicolons should all be commas.

 

[charlesstricklin]

Note that B1:B9 (column B) is not needed.

So, for our purposes, it really just exists to remind us what bracket one falls under?

Also, given the example, the correct taxes withheld should be $316.15?

 

[joeu2004]

=ROUND(SUMPRODUCT((G1>$A$2:$A$9)*(G1-$A$2:$A$9),$D$2:$D$9), 2)

Note that B1:B9 (column B) is not needed.

So, for our purposes, it really just exists to remind us what bracket one falls under?

No, not at all. I was merely pointing out the obvious: column B is not used in the SUMPRODUCT formula.

I included column B in the table only for the VLOOKUP formula, an improvement of petertenthije's approach.

I would use the SUMPRODUCT formula.

For taxable wages of $2000, the tax is: 198.40 plus 25% of (2000 - 1529); that is, 25% "of excess over" 1529.

Also, given the example, the correct taxes withheld should be $316.15?

Sure; do the math. 198.40 + 25%*(2000-1529) = 198.40 + 25%*471 = 198.40 + 117.75 = 316.15.