Calculate Payment to achieve IRR of 10% - No what-if calcs allowed

[malcolmrdj]

I have an entity in a project that receives quarterly but inconsistent cashflows until the entity's IRR = 10%.

The distribution amount is subject to available cash so one quarter's distribution could be as low as 200k or as high as whatever is available subject to 10% irr cap. Entity will always receive 200k at a minimum. Distributions will keep being made until the 10% irr has been achieved.

For example, let's say I am at 11/15/16 in table below. The payments made prior are locked in, the payments made in 2017 are guaranteed. Without using what-if, how can I back into the payment made on 11/15/16 which would create an overall irr of 10%?

Date Amount
11/15/15 ($10,000,000)
02/15/16 $200,000
05/15/16 $700,000
08/15/16 $2,500,000
11/15/16 ?
02/15/17 $200,000
05/15/17 $200,000

 

[joeu2004]

For example, let's say I am at 11/15/16 in table below. The payments made prior are locked in, the payments made in 2017 are guaranteed. Without using what-if, how can I back into the payment made on 11/15/16 which would create an overall irr of 10%?

For your example, the easiest structure might be:

	A	B	C
1	IRR	10.00%
2
3	11/15/2015	-$10,000,000
4	2/15/2016	$200,000
5	5/15/2016	$700,000
6	8/15/2016	$2,500,000
7	11/15/2016	$0	$7,106,779.52
8	2/15/2017	$200,000
9	5/15/2017	$200,000

<tbody>
</tbody>

The $0 in B7 is a placeholder; it allows us to simplify the formula.

The actual cash flow is calculated in C7 with the following formula:

=-XNPV(B1,B3:B9,A3:A9) * (1+B1)^((A7-A3)/365)

Caveat: Excel XNPV does not allow B1 (IRR) to be negative, for no good reason. If that might be an issue, we can use SUMPRODUCT instead of XNPV.

This paradigm is based on the definition of NPV; see the XNPV help page. We are solving for the missing cash flow.

If there are multiple missing cash flows, we must resort to a what-if method, generally.

 

[shg]

	A​	B​	C​	D​
1​		-70.5663%​	10.0000%​	B1 and across: =XIRR(B4:B10, $A4:$A10)
2​		(6,459,022)​	0​	B2 and across: =XNPV(10%, B4:B10, $A4:$A10)
3​	Date​	Amt​	Amt​
4​	11/15/2015​	(10,000,000)​	(10,000,000)​	C4: =B4
5​	2/15/2016​	200,000​	200,000​
6​	5/15/2016​	700,000​	700,000​
7​	8/15/2016​	2,500,000​	2,500,000​
8​	11/15/2016​	0​	7,106,780​	C8: =-B2*(1+10%)^((A8-A4)/365)
9​	2/15/2017​	200,000​	200,000​	C9: =B9
10​	5/15/2017​	200,000​	200,000​

The formula in C8 is all you need; the rest just demonstrates that it works.

 

[malcolmrdj]

Joeu/shg - many thanks on the quick replies. That did exactly what i needed..I will have to brush up on my financial theory as it has been a while.

thanks,
malcolmrdj

 

[shg]

You're welcome.