Call Macro

[erutherford]

Not sure what is causing the issue here but I do know people here will spot in a second.
I have 3 modules that I call for in another module. The main module works fine calling two other modules, but not three! Each works fine separately, but when all 3 are called "error" occurs.

Sub Openflashdrive()

Dim strFile As String
MsgBox "Select * regdwnld.xlsx * file next."
strFile = Application.GetOpenFilename(FileFilter:="Excel files, *.xlsx", Title:="Choose regdwnld file")
Workbooks.Open strFile

Call ReorderColumns
Call AutoFitColumns
Call HideColumns

End Sub

"HideColumns" causes the error "Sub or Function not defined". It works fine when run separately, but not will called. Here is the code for HideColumns

Private Sub HideColumns() 'Hide Columns

Dim wb As Workbook
Dim ws As Worksheet

Set wb = Workbooks("regdwnld.xlsx")
Set ws = wb.Worksheets("export")

ws.Activate
    ws.Range("K:BT").EntireColumn.Hidden = True
End Sub

Thanks in advance!

 

[6StringJazzer]

It can't see Private subs. Make this change:

Public Sub HideColumns() 'Hide Columns

 

[erutherford]

Told you! This group is the greatest. I'll do some homework on the diff between public and private so I know why. Thanks 6 stringer and happy rifs!

 

[6StringJazzer]

The difference is very simple:

A Private element is not visible outside of the module is declared in
A Public element is visible in any module

The rules are a little more involved when you do not explicitly say Private or Public.

• In a standard module (like Module1) if you do not specific Private or Public, a Function or Sub will default to Public.
• In a worksheet module (like Sheet1) if you do not specific Private or Public, a Function or Sub will default to Public. Regardless of whether you specified Public or allowed it to default, outside a sheet module you must explicitly qualify it to call it. For example, if Sheet1 has a Sub declared as
  

  Sub Sheet1Public()

  then the calling statement in another module must be
  

  Sheet1.Sheet1Public

• If you declare a variable with a Dim statement at the top of a module, it will default to Private. To make it Public, use Public instead of Dim.
• If you declare a constant with a const statement at the top of a module, it will default to Private. To make it Public, use Public Const.
• You cannot declare a constant as Public in a worksheet module.

There are probably other rules I am forgetting.