can you correct my code for opening and copying data from one workbook to another please

[Eurekaonide]

Hi All

can you tell me where I am going wrong here please.

I am trying to open another workbook select the data in the only worksheet it will have between Columns A:BG and as far down as the data goes in column A and copy it into the workbook I am running the code from into the worksheet "Changes".
I cant use the worksheet or workbook name that I'm opening as it could be called something new each time, however the columns are always the same the rows will differ.
Its opening but its not selecting and copying the data across into this workbook sheet "changes". Please can you help.

Sub OpenFileDialogBox()
On Error Resume Next
    
    
    Dim FilePath As String
    
    FilePath = Application.GetOpenFilename()
    
    Workbooks.Open (FilePath)
      
    ActiveWorkbook.Worksheets.Select
    Range("A:BG" & Rows.Count, "A").End(xlUp).Select
    Selection.Copy
    
    ThisWorkbook.Activate
    Sheets("Changes").Select
    Range("A1").PasteSpecial
    
      
End Sub

 

[breynolds0431]

Hi. Give the below a try:

Sub OpenFileDialogBox()

Dim tWB As Workbook: Set tWB = ThisWorkbook
Dim oFile As String: oFile = Application.GetOpenFilename()
Dim xWB As Workbook: Set xWB = Workbooks.Open(oFile)

With xWB.Sheets(1)
    .Range("A1:BG" & .Cells(.Rows.Count, 1).End(xlUp).Row).Copy
End With

With tWB.Sheets("Changes")
    .Activate
    .Range("A1").PasteSpecial
End With

'uncommment the below to close the external workbook
'xWB.Close savechanges:=False
      
End Sub

 

[jolivanes]

Or

Sub Copy_From_Closed_WB()
With Workbooks.Open(Application.GetOpenFilename)
    .Sheets(1).Cells(1).Resize(.Sheets(1).Columns(1).SpecialCells(2).Rows.Count, .Sheets(1).UsedRange.Columns.Count).Copy ThisWorkbook.Sheets("Changes").Cells(1)
    .Close False
End With
End Sub

 

[Eurekaonide]

Hi. Give the below a try:

Sub OpenFileDialogBox()

Dim tWB As Workbook: Set tWB = ThisWorkbook
Dim oFile As String: oFile = Application.GetOpenFilename()
Dim xWB As Workbook: Set xWB = Workbooks.Open(oFile)

With xWB.Sheets(1)
    .Range("A1:BG" & .Cells(.Rows.Count, 1).End(xlUp).Row).Copy
End With

With tWB.Sheets("Changes")
    .Activate
    .Range("A1").PasteSpecial
End With

'uncommment the below to close the external workbook
'xWB.Close savechanges:=False
     
End Sub

Thank you

 

[Eurekaonide]

Or

Sub Copy_From_Closed_WB()
With Workbooks.Open(Application.GetOpenFilename)
    .Sheets(1).Cells(1).Resize(.Sheets(1).Columns(1).SpecialCells(2).Rows.Count, .Sheets(1).UsedRange.Columns.Count).Copy ThisWorkbook.Sheets("Changes").Cells(1)
    .Close False
End With
End Sub

Thanks You