Can You Show Me How To Shorten This Code?

[rockyw]

I have this code I know can be shortened Can you show me where and how? Thanks

    Application.ScreenUpdating = False
    Sheets("YTD Summary DATA").Select
    Range("E3:E44").Copy Range("Q3")
    Range("E45").Select
    Application.CutCopyMode = False
    Selection.Copy
    Sheets("YTD Summary Charts").Select
    Range("E2").Select
    ActiveSheet.Paste
    Sheets("YTD Summary DATA").Select
    Range("S2").Select
    Application.CutCopyMode = False
    Selection.Copy
    Sheets("YTD Summary Charts").Select
    Range("J5").Select
    ActiveSheet.Paste
    Sheets("YTD Summary DATA").Select
    Range("H45").Select
    Application.CutCopyMode = False
    Selection.Copy
    Sheets("YTD Summary Charts").Select
    Range("T2").Select
    ActiveSheet.Paste
    Sheets("YTD Summary Charts").Select
    ActiveSheet.Deselect
    Application.ScreenUpdating = True
End Sub

 

[Rick Rothstein]

You do not have to select sheets and ranges in order to do most things (like assign values, copy /paste, etc.) with them Besides being faster, the following code, which if I read what you posted correctly should be equivalent, is also much easier to follow (at least in my opinion)...

Sub Test()
  With Sheets("YTD Summary DATA")
    .Range("E3:E44").Copy .Range("Q3")
    .Range("E45").Copy Sheets("YTD Summary Charts").Range("E2")
    .Range("S2").Copy Sheets("YTD Summary Charts").Range("J5")
    .Range("H45").Copy Sheets("YTD Summary Charts").Range("T2")
  End With
End Sub

 

[JLGWhiz]

Dim sh1 As Worksheet, sh2 As Worksheet
Set sh1 = Sheets("YTD Summary Data")
Set sh2 = Sheets("YTD Summary Charts")
Application.ScreenUpdating = False 
sh1.Range("E3:E44").Copy Range("Q3") 'Did you want to paste to the same sheet here? If not, insert sh2. in front of Range("Q3")
sh1.Range("E45").Copy sh2.Range("E2")
sh1.Range("S2").Copy sh2.Range("J5")
sh1.Range("H45").Copy sh2.Range("T2") 
Application.ScreenUpdating = True
End Sub

 

[rockyw]

Both of these return REF# instead of the data, it also copies and pastes the background colors? The cell this copys from has formulas, does that make a differance. What can I change to make this copy paste better. Thanks

 

[JLGWhiz]

Try this

Dim sh1 As Worksheet, sh2 As Worksheet
Set sh1 = Sheets("YTD Summary Data")
Set sh2 = Sheets("YTD Summary Charts")
Application.ScreenUpdating = False 
sh1.Range("E3:E44").Copy 
Range("Q3").PasteSpecial xlPasteValues 'Did you want to paste to the same sheet here? If not, insert sh2. in front of Range("Q3")
sh2.Range("E2") = sh1.Range("E45").Value
sh2.Range("J5") = sh1.Range("S2").Value 
sh2.Range("T2") = sh1.Range("H45").Value
Application.ScreenUpdating = True
End Sub