Change color of item in listview based on certain text

[Yweiss0]

Hi everyone,
I have a listview in user form contains data from a spreadsheet.
I want to loop through all items (all of them including the subitems) and change the color of the item if the item contains a text.
For example if the item (or the sub item) contains + the item should become green, if it contains * it should be blue

Thanks for the help

 

[EXCEL MAX]

Hello Yweiss0,
I hope so this piece of code will help you to understand how you can do it.

Private Sub UserForm_Initialize()

    With ListView1
        .View = lvwReport
        .ColumnHeaders.Add , , "Header1"
        .ColumnHeaders.Add , , "Header2"
        .ColumnHeaders.Add , , "Header3"
        .ListItems.Add , , "Item1*"
        .ListItems.Add , , "Item2+"
        .ListItems.Add , , "Item3*"
        .ListItems(1).SubItems(1) = "a*"
        .ListItems(1).SubItems(2) = "B++"
        .ListItems(2).SubItems(1) = "A"
        .ListItems(2).SubItems(2) = "C"
        .ListItems(3).SubItems(1) = "D"
        .ListItems(3).SubItems(2) = "***"
        
        For vN1 = 1 To .ListItems.Count
           If InStr(1, .ListItems(vN1), "+") > 0 Then _
                .ListItems(vN1).ForeColor = RGB(0, 127, 0)
           If InStr(1, .ListItems(vN1), "*") > 0 Then _
                .ListItems(vN1).ForeColor = RGB(0, 0, 255)
        Next vN1
        For vN1 = 1 To .ListItems.Count
            For vN2 = 1 To .ColumnHeaders.Count - 1
                If InStr(1, .ListItems(vN1).ListSubItems(vN2), "+") > 0 Then _
                     .ListItems(vN1).ListSubItems(vN2).ForeColor = RGB(0, 127, 0)
                If InStr(1, .ListItems(vN1).SubItems(vN2), "*") > 0 Then _
                     .ListItems(vN1).ListSubItems(vN2).ForeColor = RGB(0, 0, 255)
            Next vN2
        Next vN1
    End With
    
End Sub

 

[Yweiss0]

Thanks a million!
Just need to add end if after every if..
Works perfectly

 

[EXCEL MAX]

You are welcome.