Change Directories

[Michael68]

I am having a simple problem of getting the directory to change using VBA.
This_PC is a variable

This_PC = (Environ$("Username"))
New_Dir = "C:\Users\" & This_Pc & "\Downloads"
ChDir New_Dir

When I execute the following I open in my present directory instead of the directory I want to change to.

FileToOpen = Application.GetOpenFilename _
(Title:="Please choose a file to open", _
FileFilter:="Excel Files *.xls* (*.xls*),*.xlsm (*xlsm")
If FileToOpen <> False Then
Workbooks.Open FileName:=FileToOpen
File_Name = ActiveWorkbook.Name
Else
MsgBox "No File Selected.", vbExclamation, "Sorry!"
GoTo End_Of_File
End If

 

[DanteAmor]

Try this

Sub test()
  Dim This_Pc As String, New_Dir As String, File_Name As String
  This_Pc = (Environ$("Username"))
  New_Dir = "C:\Users\" & This_Pc & "\Downloads"
  With Application.FileDialog(msoFileDialogFilePicker)
    .Title = "Please choose a file to open"
    .Filters.Clear
    .Filters.Add "Excel Files", "*.xls*"
    .AllowMultiSelect = False
    .InitialFileName = New_Dir & "\"
    If .Show Then
      Workbooks.Open .SelectedItems.Item(1)
      File_Name = ActiveWorkbook.Name
    Else
      MsgBox "No File Selected.", vbExclamation, "Sorry!"
    End If
  End With
End Sub

 

[Tetra201]

Try inserting

ChDrive "C"

before the ChDir line.