Change red color letters by bold red color letters with underline

[MocLinh]

Hi all,

I would like to change the red color letters in excel by bold red color letters with underline. How should I do?

Example as in the image attached.

Thank you a lot for your support,

MocLinh

 

[Herakles]

Welcome to Mr Excel.

This code will ask you to select the range and then make the changes that you need to all cells in that range.

It assumes a particular colour red.

If it does not work then we need to find out what colour red is being used.

Public Sub subReformatCellValues()
Dim i As Integer
Dim rngSelected As Range
Dim rng As Range

    ActiveWorkbook.Save
    
    On Error Resume Next
    Set rngSelected = Application.InputBox(Title:="Reformatting cell values.", _
      Prompt:="Select the range of cells to reformat.", Type:=8)
    On Error GoTo 0

    If rngSelected Is Nothing Then
        Exit Sub
    End If
    
    For Each rng In rngSelected.Cells
    
        For i = 1 To Len(rng)
            If rng.Characters(i, 1).Font.Color = RGB(255, 0, 0) Then
                rng.Characters(i, 1).Font.Underline = True
                rng.Characters(i, 1).Font.Bold = True
            End If
        Next i
    
    Next rng

End Sub

 

[kevin9999]

Another option - where you specify the range of interest (and sheet name) in the code.

Option Explicit
Sub Change_Format()
    Dim ws As Worksheet
    Set ws = Worksheets("Sheet2")   '<~~ *** Change to actual sheet name ***
    Dim c As Range, i As Long
    
    For Each c In ws.Range("A1").CurrentRegion '<~~ *** Change range to actual range ***
        For i = 1 To Len(c)
            If c.Characters(i, 1).Font.Color = vbRed Then
                With c.Characters(i, 1)
                    .Font.Bold = True
                    .Font.Underline = True
                End With
            End If
        Next i
    Next c
End Sub

 

[MocLinh]

Welcome to Mr Excel.

This code will ask you to select the range and then make the changes that you need to all cells in that range.

It assumes a particular colour red.

If it does not work then we need to find out what colour red is being used.

Public Sub subReformatCellValues()
Dim i As Integer
Dim rngSelected As Range
Dim rng As Range

    ActiveWorkbook.Save
   
    On Error Resume Next
    Set rngSelected = Application.InputBox(Title:="Reformatting cell values.", _
      Prompt:="Select the range of cells to reformat.", Type:=8)
    On Error GoTo 0

    If rngSelected Is Nothing Then
        Exit Sub
    End If
   
    For Each rng In rngSelected.Cells
   
        For i = 1 To Len(rng)
            If rng.Characters(i, 1).Font.Color = RGB(255, 0, 0) Then
                rng.Characters(i, 1).Font.Underline = True
                rng.Characters(i, 1).Font.Bold = True
            End If
        Next i
   
    Next rng

End Sub

Hi Herakles,

I did it.

Thank you very much.

 

[kevin9999]

@MocLinh if @Herakles answer solved your issue, don't forget to mark it as a Solution

 

[MocLinh]

@MocLinh if @Herakles answer solved your issue, don't forget to mark it as a Solution

Hi,

Thank you to remind me.

I mark it already.