Changing Shortcut Link with VBA

[Coach3131]

I have a shortcut file called LinkURL.url... how do I change the link (properties) of the file with VBA?

 

[Coach3131]

How would you modify this code line to be able to change the shortcut target link before running? I am trying to download a csv and the link changes with dates that I want as variables

Shell "rundll32.exe shdocvw.dll,OpenURL " & (myDir & "\" & fn1), vbNormalFocus

 

[Coach3131]

Bump

 

[Coach3131]

I am not an expert with messing with the shell, but I am able to run a shortcut... but how do I change the property of the file? I would imagine someone here would be knowledgeable on the subject.

 

[John_w]

ADVERTISEMENT

Try this (edit the code where indicated) and tick MS Shell Controls and Automation in the VB editor under Tools - References.

'References Microsoft Shell Controls and Automation.
'http://msdn.microsoft.com/en-us/library/bb776890%28v=VS.85%29.aspx

Option Explicit

Public Sub Change_Shortcut()

    Dim shell As Shell32.shell
    Dim folder As Shell32.folder
    Dim folderItem As Shell32.folderItem
    Dim shortcut As Shell32.ShellLinkObject
    
    Set shell = New Shell32.shell
    
    Set folder = shell.Namespace("c:\folder\containing\the\shortcut")  'CHANGE THIS
    If Not folder Is Nothing Then
        Set folderItem = folder.ParseName("LinkURL.url")   'SHORTCUT FILE, AS PER YOUR FIRST POST
        If Not folderItem Is Nothing Then
            Set shortcut = folderItem.GetLink
            If Not shortcut Is Nothing Then
                shortcut.Path = "http://www.newurl.com/page.html"    'CHANGE THIS
                shortcut.Save
                MsgBox "Shortcut changed"
            Else
                MsgBox "Shortcut link within file not found"
            End If
        Else
            MsgBox "Shortcut file not found"
        End If
    Else
        MsgBox "Desktop folder not found"
    End If
    
End Sub

 

[rggrgg]

This worked perfectly for me, thanks

 

[donfaison]

I have been "upgraded" and my username was changed. I am not an administrator so can't run a script. ALL of my shortcuts (probably a few hundred) need to be changed from
C:\users\oldname\... to c:\users\newname\...
Any suggestions?

 

[John_w]

Please start a new thread, linking to this one if you think it would help. In the new thread tell us which folder(s) contain the shortcuts.