Clear multiple cell data based on another cell value

[mamun_ges]

I've searched but, can't get the answer is right in front of me. Need VBA code for the following condition:

I have data sheet. The range start from B9 to O1220.
In my data range I applied some condition for formatting row based on cell value.
Now if in the range of this data sheet N9 value is "Yes" then the specific cell H9, K9 & L9 data will be cleared automatically (Cell format will be unchanged)
This rules will be applied in every rows of this data or table range.
Sorry, I am not good at describe words.

Thanks in Advance.

 

[Joe4]

So, you always want to look at column N, and clear our columns H, K, and L of that same row when column N is "Yes"? Is that right?
Are you wanting to run this VBA code manually on existing data, or do you want it to run automatically upon someone updating column N with "yes"?

 

[mamun_ges]

Joe4, You are good. Thanks for early response.​

Yes, you are absolutely right. My data table start from N9 to N1220.​

This will run automatically, When ever I change in column N9, or N10 or any cell of N9 to N1220, the cell value of H, K & L of the same row will be cleared.

Thanks again in advance.

 

[Joe4]

Right-click on the sheet tab name at the bottom of the screen, select "View Code" and paste this VBA code in the resulting VB Editor window:

Private Sub Worksheet_Change(ByVal Target As Range)

    Dim rng As Range
    Dim cell As Range
    
'   If cell not updated in column N, exit sub
    Set rng = Intersect(Target, Range("N9:N1220"))
    If rng Is Nothing Then Exit Sub
    
'   Check cell in column N updated
    Application.EnableEvents = False
    For Each cell In rng
        If cell = "Yes" Then
            Cells(cell.Row, "H").ClearContents
            Range(Cells(cell.Row, "K"), Cells(cell.Row, "L")).ClearContents
        End If
    Next cell
    Application.EnableEvents = True

End Sub

This code will run autoamtically anytime a value in N9:N1220 is set to "Yes"

 

[mamun_ges]

@Joe4, Thanks you so much for the solution. I apricate your help in this regard.​

 

[Joe4]

You are welcome!