Clear Table Code not working

[gheyman]

I dont know what I changed, but this code use to work. Now it deletes everything including the header. The complete table is removed

it use to only clear all the rows with the exception of the header

Sub Clear_ItemID()

'Clear table - remove a22ll rows except the first row
    Application.ScreenUpdating = False

    ActiveSheet.ListObjects("TableItemID").HeaderRowRange.Select
'Remove the filters if one exists.
        If ActiveSheet.FilterMode Then
            Selection.AutoFilter
        End If

'Clear all lines but the first one in the table leaving formulas for the next go round.
        With Worksheets("ItemId").ListObjects("TableItemID")
            .Range.AutoFilter
        On Error Resume Next
            .DataBodyRange.Offset(1).Resize(.DataBodyRange.Rows.Count - 1, .DataBodyRange.Columns.Count).Rows.Delete
            .DataBodyRange.Rows(1).SpecialCells(xlCellTypeConstants).ClearContents
            ActiveWindow.SmallScroll Down:=-10000
      

        End With


    
    Application.ScreenUpdating = True

    Sheet1.Range("B21").Activate

End Sub

thanks for the help

 

[Fluff]

You're code work for me, but try

Sub gheyman()
   With Sheets("ItemId").ListObjects("TableItemID")
      If .ShowAutoFilter Then
         If .AutoFilter.FilterMode Then .AutoFilter.ShowAllData
      End If
      With .DataBodyRange
         .Offset(1).Resize(.Rows.Count - 1).Delete
         .SpecialCells(xlConstants).ClearContents
      End With
   End With
End Sub

 

[gheyman]

Thank you! Your code worked.

 

[Fluff]

You're welcome & thanks for the feedback

 

[gheyman]

I figured out why my original code was giving me problems. If the table was blank (didn't have more then one row) the code doesn't work.