Code for positioning a graph (Chart)

[Bob Yerby]

I am trying to create a graph which I can place in the top left hand corner of a sheet rather than in the middle of the sheet which appears to be the default. Can I do this? I have tried recording a macro to get the code, problem is that when i then run the code the graph which was called CHART 1 is now called CHART 2.
I did try ActiveChart.Name="MyGraph" but that didn't work (it was only a guess).
Any help greatly appreciated. (I do not care what the graph is called, I just want to control where it appears on the screen).

Bob

 

[VoG]

Try

Sub MovCht()
With ActiveSheet.ChartObjects(ActiveSheet.ChartObjects.Count)
    .Top = Range("A1").Top
    .Left = Range("A1").Left
End With
End Sub

 

[Bob Yerby]

Thanks - that was very helpful.

 

[pgc01]

Hi Bob
Welcome to the board

I usually position the chartobject when I create it, and name it immediately after.

Ex. Suppose a simple column chart, X values in Sheet1!A2:A5, Y values in Sheet1!B2:B5.

If you want to create the chart in the top left had corner of Sheet1, for ex.:

Sub CreateChart()
Dim ws As Worksheet
Dim rX As Range, rY As Range
Dim chtO As ChartObject
 
Set ws = Worksheets("Sheet1")
Set rX = ws.Range("A2:A5")
Set rY = ws.Range("B2:B5")
 
Set chtO = ws.ChartObjects.Add(0, 0, 400, 200)
chtO.Name = "Mychart"
 
With chtO.Chart
    With .SeriesCollection.NewSeries
       .ChartType = xlColumnClustered
       .Values = rY
       .XValues = rX
    End With
End With
End Sub