Code to enable user to select multiple worbooks

[howard]

I have the following code that enables a user to select a workbook in a particular folder


I would like this amended so that the user can select which workbooks he/she wants to select

 Sub Open_bank()
ChDir "C:\bank"
Dim nb As Workbook, ts As Worksheet, A As Variant
       
    Set ts = ActiveSheet
      A = Application.GetOpenFilename
    If A = False Or IsEmpty(A) Then Exit Sub
    
    Application.ScreenUpdating = False
    
    Set nb = Workbooks.Open(A)
    ThisWorkbook.Activate
 
End Sub

Your assistance in this regard is most appreciated

 

[mikerickson]

Try

Dim SelectedFileNames as Variant
Dim oneFileName as Variant

SelectedFileNames = Application.GetOpenFileName(MultiSelect:=True)

if SelectedFileNames = False then Exit Sub

For each oneFileName in SelectedFileNames
    Workbooks.Open oneFileName
Next oneFileName

 

[howard]

Thanks for the help, much appreciated

 

[howard]

When I open several files I get type mismatch and the following code is highlighted

 If SelectedFileNames = False Then Exit Sub

Kindly amend code so that I can select more than one file to open

 

[dmt32]

hi,
see if following does what you want:

Sub OpenMultiSelection()
    Dim SelectedFiles As Variant
    Dim i As Integer

    SelectedFiles = Application.GetOpenFilename(MultiSelect:=True)
    If VarType(SelectedFiles) = vbBoolean Then Exit Sub
    
    For i = LBound(SelectedFiles) To UBound(SelectedFiles)
        Workbooks.Open Filename:=SelectedFiles(i)
    Next i

End Sub

Dave

 

[howard]

Hi Dave

Thanks for the help. Have just tested your code & it works perfectly

 

[dmt32]

Hi Dave

Thanks for the help. Have just tested your code & it works perfectly

Most welcome glad I could help.

many thanks for your feedback

Dave