Combining Macro's

[DavidVernon]

Hi everyone
I'm trying to combine the two macro's below so that they can be ran from one button. I'm struggling because of the scripting.dictionary. Because both macro's use this object, I'm not sure if it is possible to combine them. Any thoughts?

Sub delete_duplicate_invoice_values()

Dim Rng As Range, Dn As Range
Dim Txt As String, Ray
With CreateObject("scripting.dictionary")
.comparemode = vbTextCompare
Set Rng = Range(Range("U2"), Range("U" & Rows.Count).End(xlUp))
ReDim Ray(1 To Rng.Count, 1 To 3)
For Each Dn In Rng
Txt = Dn & Dn.Offset(, -20) & Dn.Offset(, -17)
If Not .Exists(Txt) Then
.Add Txt, ""
Else
Dn.Resize(, 1).ClearContents
End If
Next Dn
End With
End Sub

Sub delete_duplicate_credit_foc_values()

Dim Rng As Range, Dn As Range
Dim Txt As String, Ray
With CreateObject("scripting.dictionary")
.comparemode = vbTextCompare
Set Rng = Range(Range("T2"), Range("T" & Rows.Count).End(xlUp))
ReDim Ray(1 To Rng.Count, 1 To 3)
For Each Dn In Rng
Txt = Dn & Dn.Offset(, -19) & Dn.Offset(, -16)
If Not .Exists(Txt) Then
.Add Txt, ""
Else
Dn.Resize(, 1).ClearContents
End If
Next Dn
End With
End Sub

 

[EducatedFool]

Try

Sub delete_duplicate(ByVal Col As String)
    Dim Rng As Range, Dn As Range
    Dim Txt As String, Ray
    With CreateObject("scripting.dictionary")
        .comparemode = vbTextCompare
        Set Rng = Range(Cells(2, Col), Cells(Rows.Count, Col).End(xlUp))
        ReDim Ray(1 To Rng.Count, 1 To 3)
        For Each Dn In Rng
            Txt = Dn & Dn.EntireRow.Cells(1) & Dn.EntireRow.Cells(4)
            If Not .Exists(Txt) Then .Add Txt, "" Else Dn.ClearContents
        Next Dn
    End With
End Sub

Sub test()
    [B]delete_duplicate "U"
    delete_duplicate "T"[/B]
End Sub

 

[DavidVernon]

Thanks for answering EducatedFool - it looks so close, but my offset conditions change from one to the other. How could they be included?

 

[EducatedFool]

but my offset conditions change from one to the other. How could they be included?

I have not found any offset in my macro...

My macro is a complete analogue of 2 of your macros

 

[DavidVernon]

You are a genius! I have now had time to test your code and it works perfectly - Thank you so much