Complicated Question! Need Help!

[klasikrecords]

I need to add 2 additional parameters to the following formula.

=IF(ROWS(A$12:A12)<=$A$4,SMALL(
IF('Training Database'!$A$2:'Training Database'!$A$4996=$D$5,
ROW('Training Database'!$A$2:'Training Database'!$A$4996)-ROW('Training Database'!$A$2)+1),ROWS(A$12:A12)),"")

The bolded portion of the formula matches and emplyees name. I also want to add a date range. So the next piece would be something like 'Training Database'!$F$2:'Training Database'!$F$4996>=$D$6 and then 'Training Database'!$A$2:'Training Database'!$A$4996<=$D$7

But I cannot get this to work out correctly. Can someone please let m eknow how I can add those 2 parameters to the formula at the top?

Thanks soooo much!

 

[AlphaFrog]

Try something like this (not tested)...

=IF(ROWS(A$12:A12)<=$A$4,SMALL(
IF(('Training Database'!$A$2:$A$4996=$D$5)*
('Training Database'!$F$2:$F$4996>=$D$6)*
('Training Database'!$F$2:$F$4996<=$D$7),
ROW('Training Database'!$A$2:'$A$4996)-ROW('Training Database'!$A$2)+1),ROWS(A$12:A12)),"")

 

[klasikrecords]

That works, thank you for taking the time to respond!

 

[Aladin Akyurek]

Try...

=IF(ROWS(A$12:A12)<=$A$4,SMALL(
     IF('Training Database'!$A$2:$A$4996=$D$5,
     IF('Training Database'!$F$2:$F$4996>=$D$6,
     IF('Training Database'!$F$2:$F$4996<=$D$7,
       ROW('Training Database'!$A$2:$A$4996)-
         ROW('Training Database'!$A$2)+1))),ROWS(A$12:A12)),"")