Conditional Message Box

[Excel Ent]

Hello group
I am trying to figure out how to create a series of message boxes that if three conditions are met, it runs the macro.

1.) First a message box will ask for the user to input a value.
2.) It the user cancels or enters a blank it will exit the sub
3.) The value of the user input will be compared against a range say (A1 THRU A20).
1a.) if the value is not in the range a message box will alert that the value in not in the range and ask the user if they want to try again
1b.) if the user hits yes, it will loop to enter another value, if not it will exit the sub
1c.) if the value is in the range then the macro will run

Appreciate any responses


Kind Regards!

 

[Yongle]

try something like this

Sub test5()
    Dim aValue
EnterValue:
    aValue = InputBox("Enter a value")
    If Len(aValue) = 0 Then
        GoTo TheEnd
    ElseIf WorksheetFunction.CountIf(Range("A1:A20"), aValue) = 0 Then
        If MsgBox("Not in range ... try again?", vbYesNo, "???") = vbYes Then GoTo EnterValue Else GoTo TheEnd
    Else
        'Call YourMacro
    End If
Exit Sub
TheEnd:
MsgBox "Cancelled by user"
End Sub

if you experience any problems let me know what type of values are being matched in A1:A20
- VBA may require more information

 

[Fluff]

Another option

Sub ExcelEnt()
   Dim Ans As Variant
   Dim Flg As Boolean
   
   Do
      Ans = InputBox("Enter a value")
      If Ans = "" Then Exit Sub
      If Application.CountIf(Range("A1:A20"), Ans) > 0 Then
         Flg = True
      End If
      If Not Flg Then If MsgBox(Ans & " Not found. Do you want to try again", vbYesNo) = vbNo Then Exit Sub
   Loop Until Flg
End Sub

 

[Excel Ent]

Very nice! You are a master of the craft...…... Love the sub name.

 

[Fluff]

Glad we could help & thanks for the feedback.