converting alternate row in coloumn

[livinggourmand]

I have a vocabulary list,but word& meaning is in 1 row and sentence example in row below
i want it to be side by side as shown in image.
Kindly help

 

[livinggourmand]

sorry image didnt come properly
here it is

 

[Rick Rothstein]

Does definition #4's example really occupy two rows as shown (as opposed to being in a single cell with wrapped text)?

Are all your words always going to be single words (as opposed to two-word entries like "scarlet fever")?

 

[livinggourmand]

@Rick Rothstein
sorry for late reply

yes, few definitions occupy more rows (thats a close inspections... thanks)
and all words always going to be single words

 

[Rick Rothstein]

Give this macro a try...

Sub RearrangeWordsDefinitionsAndExamples()
  Dim X As Long, LastRow As Long, Definition As String, A As Range, Data() As String
  LastRow = Cells(Rows.Count, "A").End(xlUp).Row
  With Range("B1").Resize(LastRow)
    .FormulaR1C1 = "=IF(ISNUMBER(--LEFT(RC[-1])),SUBSTITUTE(MID(RC[-1],FIND("" "",RC[-1])+1,999),"" "",CHAR(1),1),"""")"
    .Value = .Value
    For Each A In .SpecialCells(xlCellTypeBlanks).Areas
      If A.Rows.Count > 1 Then
        Definition = Join(WorksheetFunction.Transpose(A.Offset(, -1)))
      Else
        Definition = A.Offset(, -1).Value
      End If
      A(1).Offset(-1).Value = A(1).Offset(-1).Value & Chr(1) & Definition
    Next
    .SpecialCells(xlCellTypeBlanks).EntireRow.Delete
    .TextToColumns Range("B1"), xlDelimited, , , False, False, False, False, True, Chr(1)
  End With
  Columns("A").Delete
  Rows(1).Insert
  With Range("A1:C1")
    .Value = Array("Word", "Meaning", "Sentence Example")
    .Interior.ColorIndex = 6
    .EntireColumn.Columns.AutoFit
  End With
End Sub

 

[livinggourmand]

@Rick Rothstein

hey it worked!!!!!!!!!!!!!!!!!!!!!
i appreciate ur quick response with perfect solution

Thanks a lot.

ok if possible can u explain ur macro to me.
i kno thats way too much bt it ll help me understand macros

thanks again