Converting quarter to months

onthegreen03

Board Regular
Joined
Jun 30, 2016
Messages
148
Office Version
  1. 365
Platform
  1. Windows
Hi - I want to convert a given quarter to months. So, if in cell A1 I have 'Q1 2021', I want to return 'Jan 2021', 'Feb 2021' and 'Mar 2021' in cells A2 through A4. I know how to convert months to quarter, just can't figure out the reverse. Thanks!
 
Last edited:

Excel Facts

Bring active cell back into view
Start at A1 and select to A9999 while writing a formula, you can't see A1 anymore. Press Ctrl+Backspace to bring active cell into view.
=TEXT(DATE(RIGHT(A1,4),(MID(A1,2,1)*3)-2,1),"Mmm YYYY")
=TEXT(DATE(RIGHT(A1,4),(MID(A1,2,1)*3)-1,1),"Mmm YYYY")
=TEXT(DATE(RIGHT(A1,4),(MID(A1,2,1)*3),1),"Mmm YYYY")
 
Upvote 0
Using dynamic array functions.

FactSheet_Data_New (8).xlsx
AB
1Q1 2021Q3 2022
2Jan 2021Jul 2022
3Feb 2021Aug 2022
4Mar 2021Sep 2022
Sheet2
Cell Formulas
RangeFormula
A2:B4A2=FILTER({"Jan";"Feb";"Mar";"Apr";"May";"Jun";"Jul";"Aug";"Sep";"Oct";"Nov";"Dec"},{"Q1";"Q1";"Q1";"Q2";"Q2";"Q2";"Q3";"Q3";"Q3";"Q4";"Q4";"Q4"}=LEFT(A1,2))&" " &RIGHT(A1,4)
Dynamic array formulas.
 
Upvote 0
Another option
+Fluff 1.xlsm
AB
1Q1 2021Q3 2022
2Jan 2021Jul 2022
3Feb 2021Aug 2022
4Mar 2021Sep 2022
Main
Cell Formulas
RangeFormula
A2:B4A2=FILTER(TEXT(DATE(RIGHT(A1,4),SEQUENCE(12),1),"mmm"),"Q"&INT(SEQUENCE(12,,,1/3))=LEFT(A1,2))&" " &RIGHT(A1,4)
Dynamic array formulas.
 
Upvote 0
Solution
Or another:

=TEXT(DATE(RIGHT(A1,4),SEQUENCE(3,,MID(A1,2,1)*3-2,1),1),"mmm yyyy")
 
Upvote 0
Thanks all for your responses. All great options (they all worked). I really appreciate the support on this board!
 
Upvote 0
Glad we could help & thanks for the feedback.
 
Upvote 0

Forum statistics

Threads
1,213,484
Messages
6,113,924
Members
448,533
Latest member
thietbibeboiwasaco

We've detected that you are using an adblocker.

We have a great community of people providing Excel help here, but the hosting costs are enormous. You can help keep this site running by allowing ads on MrExcel.com.
Allow Ads at MrExcel

Which adblocker are you using?

Disable AdBlock

Follow these easy steps to disable AdBlock

1)Click on the icon in the browser’s toolbar.
2)Click on the icon in the browser’s toolbar.
2)Click on the "Pause on this site" option.
Go back

Disable AdBlock Plus

Follow these easy steps to disable AdBlock Plus

1)Click on the icon in the browser’s toolbar.
2)Click on the toggle to disable it for "mrexcel.com".
Go back

Disable uBlock Origin

Follow these easy steps to disable uBlock Origin

1)Click on the icon in the browser’s toolbar.
2)Click on the "Power" button.
3)Click on the "Refresh" button.
Go back

Disable uBlock

Follow these easy steps to disable uBlock

1)Click on the icon in the browser’s toolbar.
2)Click on the "Power" button.
3)Click on the "Refresh" button.
Go back
Back
Top