Copy and Paste value from one workbook to another

[hajiali]

Sub PullFinalBidData()
  Dim wb As Workbook, fullpath As String
  Dim wt As Worksheet
  Set wt = Sheets("BID")
  With Application.FileDialog(msoFileDialogFilePicker)
    .AllowMultiSelect = False
    .Filters.Add "Excel Files", "*.xlsm", 1
    If .Show <> -1 Then Exit Sub
    fullpath = .SelectedItems.Item(1)
    Set wb = Workbooks.Open(fullpath)
    wb.Sheets("RA Print").Range("E5:S303").Copy ThisWorkbook.Sheets("TOOL DATA").Range("B3")
    wb.Sheets("RA Print").Range("E304:S604").Copy ThisWorkbook.Sheets("TOOL DATA").Range("B303")
    wb.Close False
  End With
End Sub

Using the above code it copies the data but uses just paste. How would I be able to make this paste Value.

 

[JLGWhiz]

Like this

Sub PullFinalBidData2()
  Dim wb As Workbook, fullpath As String
  Dim wt As Worksheet
  Set wt = Sheets("BID")
  With Application.FileDialog(msoFileDialogFilePicker)
    .AllowMultiSelect = False
    .Filters.Add "Excel Files", "*.xlsm", 1
    If .Show <> -1 Then Exit Sub
    fullpath = .SelectedItems.Item(1)
    Set wb = Workbooks.Open(fullpath)
    wb.Sheets("RA Print").Range("E5:S303").Copy
    ThisWorkbook.Sheets("TOOL DATA").Range("B3").PasteSpecial xlPasteValues
    wb.Sheets("RA Print").Range("E304:S604").Copy
    ThisWorkbook.Sheets("TOOL DATA").Range("B303").PasteSpecial xlPasteValues
    wb.Close False
  End With
End Sub

 

[hajiali]

Thanks JLGWhiz that works great.

I am getting the Microsoft Excel Message about "There is a large amount of information on the clipboard. Do you want to be able to paste this information into another program Later? with option Yes No and Cancel.

Is there a way to prevent that message to appering?

 

[JLGWhiz]

 ThisWorkbook.Sheets("TOOL DATA").Range("B303").PasteSpecial xlPasteValues
 Application.CutCopyMode = False
  wb.Close False

add the line in blue as shown. That should clear the clipboard.