Copy cell formatting to embedded object

[stewart1]

Evening to all.

I've embedded a word document which I managed to cobble code together to open.

Sub Macro4()
'
' Macro4 Macro
'

'

Dim wDoc As Object 'Word.Document
    With ActiveSheet
    ActiveCell.Copy
  Set o = .OLEObjects("Object 5")
  o.Verb xlVerbOpen
  ActiveSheet.Shapes.Range(Array("Object 5")).Select
    Selection.Verb Verb:=xlPrimary
    
 End With
End Sub

I'm a bit stuck on copying the cell contents to it via vba. Keeping all the cell formatting. Once the word doc opens, no more code is recorded.

Can anyone give me any ideas please?

As always really appreciated you taking the time to read.

Stu

 

[Domenic]

Try to adapt the following code...

Option Explicit

Sub test()

    Dim targetWorksheet As Worksheet
    Set targetWorksheet = ActiveSheet
    
    Dim targetCell As Range
    Set targetCell = ActiveCell

    Dim embeddedObject As OLEObject
    Set embeddedObject = targetWorksheet.OLEObjects("Object 5")
    embeddedObject.Verb Verb:=xlVerbPrimary
    
    Dim wordDocument As Object
    Set wordDocument = embeddedObject.Object
    
    targetCell.Copy
    With wordDocument
        With .Parent
            .Selection.EndKey Unit:=6 'wdStory
            .Selection.TypeParagraph
            .Selection.TypeParagraph
            .Selection.PasteAndFormat 16 'wdFormatOriginalFormatting
        End With
    End With
    
    Application.CutCopyMode = False
    
    Set wordDocument = Nothing
    Set embeddedObject = Nothing
    Set targetWorksheet = Nothing
    
End Sub

Hope this helps!

 

[stewart1]

You Domenic are an absolute legend! All last night I was trying to do this.... And tonight I will work on sending it back to the active cell with formatting.....

Honestly, really appreciate it Domenic!??

 

[Domenic]

That's great, I'm really glad to help, cheers!