Copy data from multiple shheets to master sheet VBA

[cams88]

Hello,

I want to copy data from multiple sheets (dynamic columns and rows) to one master sheet but my code doesn't work and i don't have any idea where is a problem... I would be very grateful for any help.

My code:

Sub copy_data_to_master_sheet()

Rowsnotmaster = Range("A1048576").End(xlUp).Row
Columnsnotmaster = Range("XFD3").End(xlToLeft).Column

For i = 2 To Worksheets.Count

'copy data from multiple sheets

Worksheets(i).Range(Cells(3, 1), Cells(Rowsnotmaster, Columnsnotmaster)).Copy
Worksheets("Master").Select

'paste data to master sheet

Master_row = Cells(Rows.Count, 1).End(xlUp).Row + 1
Selection.Cells(Master_row, 1).PasteSpecial

Next

End Sub

 

[JackDanIce]

Try:

Sub Tango()

    Dim a   As Variant
    Dim w   As Worksheet
    Dim m   As Worksheet: Set m = Sheets("Master")
    
    Application.ScreenUpdating = False
    
    For Each w In ThisWorkbook.Worksheets
        If w.Name <> m.Name Then
            With w
                a = .Cells(3, 1).Resize(.Cells(.Rows.Count, 1).End(xlUp).Row - 2, .Cells(3, .Columns.Count).End(xlToLeft).Column).Value
            End With
            m.Cells(Rows.Count, 1).End(xlUp).Offset(1).Resize(UBound(a, 1), UBound(a, 2)).Value = a
        End If
    Next w
    
    Application.ScreenUpdating = True
    
    m.Activate
    
    Set m = Nothing: Erase a

End Sub

 

[cams88]

It doesn't work:

 

[JackDanIce]

On what line does that occur?

I created a workbook with 3 sheets, Master, Data and Data (2)

In Data I filled A3:O25 with "X"
In Data (2) I filled A3:J40 with "A"

Ran macro and Master contains values of "X" in range A2:O24 and "A" in Range A25:J62 without any errors