Copy entire row if cell contains specific text and paste values into others worksheets

[edsonpaula]

Hello, I have a worksheet with many rows and I need to copy and paste the entire row (paste value) to other sheets based on the value in column F.
I’m running the code below, but I’m not able to remove the blanc lines in the target sheet and paste values only, can someone help with that?

Sub macro1()

Dim c As Range
Dim j As Integer
Dim Source As Worksheet
Dim Target As Worksheet
Dim Target1 As Worksheet

Set Source = ActiveWorkbook.Worksheets("Sheet1")
Set Target = ActiveWorkbook.Worksheets("Sheet2")
Set Target1 = ActiveWorkbook.Worksheets("Sheet3")

j = 1
For Each c In Source.Range("F1:F" & Cells(Rows.Count, 1).End(xlUp).Row)
If c = "Ações" Then Source.Rows(c.Row).Copy Target.Rows(j)
If c = "Outros" Then Source.Rows(c.Row).Copy Target1.Rows(j)
j = j + 1
Next c

End Sub

 

[Fluff]

Hi & welcome to MrExcel.
How about

Sub macro1()

Dim c As Range
Dim Source As Worksheet
Dim Target As Worksheet
Dim Target1 As Worksheet

Set Source = ActiveWorkbook.Worksheets("Sheet1")
Set Target = ActiveWorkbook.Worksheets("Sheet2")
Set Target1 = ActiveWorkbook.Worksheets("Sheet3")

For Each c In Source.Range("F1:F" & Source.Cells(Rows.Count, 1).End(xlUp).Row)
   If c = "Ações" Then
      c.EntireRow.Copy
      Target.Range("A" & Rows.Count).End(xlUp).Offset(1).PasteSpecial xlPasteValues
   ElseIf c = "Outros" Then
      c.EntireRow.Copy
      Target1.Range("A" & Rows.Count).End(xlUp).Offset(1).PasteSpecial xlPasteValues
   End If
Next c
End Sub

 

[edsonpaula]

Hi & welcome to MrExcel.
How about

Sub macro1()

Dim c As Range
Dim Source As Worksheet
Dim Target As Worksheet
Dim Target1 As Worksheet

Set Source = ActiveWorkbook.Worksheets("Sheet1")
Set Target = ActiveWorkbook.Worksheets("Sheet2")
Set Target1 = ActiveWorkbook.Worksheets("Sheet3")

For Each c In Source.Range("F1:F" & Source.Cells(Rows.Count, 1).End(xlUp).Row)
   If c = "Ações" Then
      c.EntireRow.Copy
      Target.Range("A" & Rows.Count).End(xlUp).Offset(1).PasteSpecial xlPasteValues
   ElseIf c = "Outros" Then
      c.EntireRow.Copy
      Target1.Range("A" & Rows.Count).End(xlUp).Offset(1).PasteSpecial xlPasteValues
   End If
Next c
End Sub

It worked perfect! Thank you very much!!!!

 

[Fluff]

You're welcome & thanks for the feedback.

 

[edsonpaula]

@Fluff let me ask you another stupid question.
I'd like to clean all those sheets before running this macro, I have created a private sub to delete the rows, and worked fine, but I'm having trouble making it run in all sheets in the range, any idea how can I accomplish it?

Private Sub DeleteRows()
   
    Range("A3:AC3").Select
    Range(Selection, Selection.End(xlDown)).Select
    Selection.EntireRow.Delete
End Sub

Thank you very much for all the help!

Edson

 

[Fluff]

As that's a completely different question, it needs a new thread. Thanks

 

[edsonpaula]

Sure thing! thank you!