Copy Macro

[wazzulu1]

Hi;

I am trying to create a macro that will copy rows of data from one tab in a workbook, to another, based on a checkbox value of true in column AR.

If the box is checked, meaning true:

if ar = true

then

copy row from customer file to flash report

after row 10

columns A:AS

Appreciate any insight, as I seek to move from being a newbie to a moderate with Excel.

 

[HalfAce]

Hi wazzulu1,
Are you wanting to copy all rows that have 'True' in column AR?
Do you want to copy the entire row(s), or just columns A:AS?
Do you want these pasted in the 'flash report' sheet starting in column A?
What is the actual name of the 'flash report' sheet?
(And you want the pasted rows to start in row 11, right?)

 

[wazzulu1]

Hi Halface!

Thanks for the inquiry, my answers are next to each question:

Hi wazzulu1,
Are you wanting to copy all rows that have 'True' in column AR? (YES)
Do you want to copy the entire row(s), or just columns A:AS? (Columns A:AS
Do you want these pasted in the 'flash report' sheet starting in column A?(YES)
What is the actual name of the 'flash report' sheet? (FLASH REPORT)
(And you want the pasted rows to start in row 11, right?) (YES)
_________________

 

[HalfAce]

You're most welcome.
Try this and see if it's what you're looking for.
(Meant to be run with the sheet containing 'TRUE' in column AR as the active sheet, and
assumes you do in fact have a sheet named 'FLASH REPORT')

Sub Demo()
Dim LstRw As Long, DestRw As Long
LstRw = Cells(Rows.Count, "AR").End(xlUp).Row
With Sheets("FLASH REPORT")
  If .Range("A11") = "" Then
    DestRw = 11
  Else
    DestRw = .Cells(Rows.Count, "A").End(xlUp)(2).Row
  End If
End With
ActiveSheet.AutoFilterMode = False
On Error GoTo Quit

Columns("AR:AR").AutoFilter Field:=1, Criteria1:="TRUE"
Range("A2:AS" & LstRw).SpecialCells(xlCellTypeVisible).Copy _
  Sheets("FLASH REPORT").Cells(DestRw, "A")
  
Quit:
ActiveSheet.AutoFilterMode = False
End Sub

 

[wazzulu1]

This works perfect!


I'm in the process of ordering the Slide into VBA CD, but I really do need help with stuff like this in the interim.


Thank you so much!

 

[HalfAce]

You're welcome. Glade it helped.

I'm not familiar with slide into VBA. If you're getting it from the Online store here I'm
sure it'll be worth having.