Correctly Cancel or close Input Box to exit sub

[Knockoutpie]

I'm attempting to have the Cancel Button or Close Button on the input box to exit the sub, can anyone assist in executing that correctly?

Sub openurl()

Dim EdgeLocation As String
Dim MyURL As String
Dim i As Integer
Dim ws1 As Worksheet
Dim lastRow As Long
Dim inputValue As Variant ' n


range("A1").Select

lastRow = Cells.Find("*", SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row

Set ws1 = Sheets("Page1_1")

EdgeLocation = "C:\Program Files (x86)\Microsoft\Edge\Application\msedge.exe" 'Location of Edge.exe in your PC

For i = 1 To lastRow

    ' Copy the adjacent value in column CM
    Dim valueToCopy As String
    valueToCopy = ActiveSheet.range("CL" & i).Value
    ActiveSheet.range("CL" & i).Copy

   '  ActiveSheet.range("CL" & i).EntireRow.Interior.Color = RGB(0, 255, 0)

MyURL = ws1.Cells(i, 1)
    Shell (EdgeLocation & " -url -newtab " & MyURL)
    
    
     ActiveSheet.range("CN" & i) = InputBox("Enter Y or N for POD", "InputBox Example")
         If inputValue = "" Then
        End
    Else
        ' Do something with the input value
    End If
     
            range("CN1").Select
    ActiveCell.FormulaR1C1 = "POD"
    
    
    

Next i


End Sub

 

[DanteAmor]

Check this:

Sub test_inputbox()
  Dim inputValue   As String
  inputvalue = InputBox("Enter Y or N for POD", "InputBox Example")
  If StrPtr(inputValue) = 0 Then
    MsgBox "Click Cancel, exit now"
    Exit Sub
  ElseIf Len(inputValue) = 0 Then
    MsgBox "Please Enter Y or N"
  Else
    Select Case UCase(inputValue)
      Case "Y"
        'Your code in case Y
      Case "N"
        'Your code in case N
      Case Else
        MsgBox "Please enter: Y or N"
    End Select
  End If
End Sub

Or this:

Sub test_vbyesno()
  Dim inputvalue As VbMsgBoxResult
  inputvalue = MsgBox("Enter Yes or No for POD", vbQuestion + vbYesNo, "InputBox Example")
  If inputvalue = vbYes Then
    'Your code in case Y
  Else
    'Your code in case N
  End If
End Sub