Count occurrences in a row with multiple criteria

[mo70ss]

I am struggling to write a formula that will count the number of times a given number has appeared with another given number. Each day there are 5 numbers drawn between 1 and 10. I need to know how times times lets say the number 1 and the number 2 have appeared in the same row.
Below is a sample of what it should look like. For example, the number 1 has appeared in the same row with the number 2 1 time. The number 5 has appeared in the same row with the number 6 3 different times.
Any help would be greatly appreciated!! Thank you in advance.

Draw	Date	#1	#2	#3	#4	#5		#	1	2	3	4	5	6	7	8	9	10
1	6/1/2020​	1	2	3	4	10		1		1	1	1						1
2	6/2/2020​	2	5	6	7	9		2	1		1	1	1	1	1		1	1
3	6/3/2020​	3	4	5	7	8		3	1	1		2	1		1	1		1
4	6/4/2020​	4	5	6	8	9		4	1	1	2		2	1	1	2	1	1
5	6/5/2020​	5	6	7	8	9		5		1	1	2		3	3	3	3
								6		1		1	3		2	2	3
								7		1	1	1	3	2		2	2
								8			1	2	3	2	2		2
								9		1		1	3	3	2	2
								10	1	1	1	1

 

[Eric W]

Welcome to the MrExcel forums!

There's probably a better way, but this was my first idea and it worked:

Book1
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S
1	Draw	Date	#1	#2	#3	#4	#5		#	1	2	3	4	5	6	7	8	9	10
2	1	6/1/2020	1	2	3	4	10		1		1	1	1	0	0	0	0	0	1
3	2	6/2/2020	2	5	6	7	9		2	1		1	1	1	1	1	0	1	1
4	3	6/3/2020	3	4	5	7	8		3	1	1		2	1	0	1	1	0	1
5	4	6/4/2020	4	5	6	8	9		4	1	1	2		2	1	1	2	1	1
6	5	6/5/2020	5	6	7	8	9		5	0	1	1	2		3	3	3	3	0
7									6	0	1	0	1	3		2	2	3	0
8									7	0	1	1	1	3	2		2	2	0
9									8	0	0	1	2	3	2	2		2	0
10									9	0	1	0	1	3	3	2	2		0
11									10	1	1	1	1	0	0	0	0	0
Sheet1

Cell Formulas
Range	Formula
J2:S11	J2	=IF(J$1=$I2,"",SUMPRODUCT(MMULT(--($C$2:$G$10=$I2),{1;1;1;1;1})*MMULT(--($C$2:$G$10=J$1),{1;1;1;1;1})))

 

[mo70ss]

You are awesome Eric.!! You have no idea how long I've been working on this. Your solution works great!! Thank you so much!!

 

[Eric W]

Glad to help! That was a fun one. Here's a slightly shorter version of it:

=IF(J$1=$I2,"",SUMPRODUCT(--(MMULT(($C$2:$G$10=$I2)+($C$2:$G$10=J$1),{1;1;1;1;1})=2)))

 

[mo70ss]

I like this version even better. I had never used, or was even aware of the MMULT function. Thanks again Eric!!