Count words in column (with cells having more than 1 word)

[goble]

Hi,

I have a column (data) with words separated by comas. I would like to count how many times the words appear.

I have seen a similar post in this forum where you define the words and then you get the word count. Here I need to get both the list of the words (Column B) and their occurrence (Column C).

Thanks !

Data	Result 1	Result 2 (Count)
boy,girl,man,woman	aunt	3
uncle,aunt,father	boy	2
aunt,man,boy	father	2
woman,father,aunt	girl	1
	man	2
	uncle	1
	woman	2

 

[Joe4]

Assuming your column A data is in cells A2:A5, and "aunt" is in B2, put this formula in cell C2:

=SUMPRODUCT(--(ISNUMBER(SEARCH($B2,$A$2:$A$5))))

and copy down.

 

[goble]

Hi and thanks @Joe4

However I don't have the list in Column C. I need excel to find the (specific) words and then count them.

 

[Rick Rothstein]

Assuming your data is in Column A starting at Row 2 (where Row 1 is assumed to be the headers you show), then this macro will produce the two result lists shown in Columns B and C...

Sub GetWordsAndCount()
  Dim N As Long, X As Long, Words As Variant, Arr As Variant
  Arr = Range("A2", Cells(Rows.Count, "A").End(xlUp))
  With CreateObject("Scripting.Dictionary")
    For X = 1 To UBound(Arr)
      Words = Split(Arr(X, 1), ",")
      For N = 0 To UBound(Words)
        .Item(Words(N)) = .Item(Words(N)) + 1
      Next
    Next
    Range("B2").Resize(.Count) = Application.Transpose(.Keys)
    Range("C2").Resize(.Count) = Application.Transpose(.Items)
    Range("B2:C2").Resize(.Count).Sort Range("B2")
  End With
End Sub

HOW TO INSTALL MACROs
------------------------------------
If you are new to macros, they are easy to install and use. To install it, simply press ALT+F11 to go into the VB editor and, once there, click Insert/Module on its menu bar, then copy/paste the above code into the code window that just opened up. That's it.... you are done. To use the macro, go back to the worksheet with your data on it and press ALT+F8, select the macro name (GetWordsAndCount) from the list that appears and click the Run button. The macro will execute and perform the action(s) you asked for. If you will need to do this again in this same workbook, and if you are using XL2007 or above, make sure you save your file as an "Excel Macro-Enabled Workbook (*.xlsm) and answer the "do you want to enable macros" question as "yes" or "OK" (depending on the button label for your version of Excel) the next time you open your workbook.

 

[goble]

Thank you !

I'm incredibly amazed by the level of support you provide ! Again thank you so much !