Counting number of triads

[lculph]

I'm trying to count the number of triads completed in a Y-Maze test (see im

age)
A complete triad is when a mouse moves from B > C > A, B > A > C, C > A > B etc. If the mouse goes B > A > B the triad in not complete.

My data is expressed just as a list of BABABCBAB etc.
Is there a way I can count the amount of triads complete? If there is a direction change from clockwise to anti-clockwise that is ok, as long as the triad is complete.

Thanks!

 

[Snakehips]

@lculph Welcome
Can you clarify a couple of points?
Is your list one letter per row?
Indication of typical max number of rows?
Are the triads mutually exclusive such that in this example the count is 2 not 3 ?

Book1
	A	B
2	B
3	A
4	B
5	A
6	B
7	C
8	B
9	A
10	B
11	C
12
Sheet1

 

[Snakehips]

A Google would lead me to believe that the triads (SAPs) are not necessarily discrete.
So maybe along these lines might help?
Utilising a helper column which could be hidden if required.

Book1
	A	B	C	D
1	Arm		Triad	Triad Total
2	C			13
3	B
4	C		0
5	A		1
6	B		1
7	A		0
8	B		0
9	A		0
10	C		1
11	A		0
12	B		1
13	A		0
14	C		1
15	A		0
16	B		1
17	B		0
18	C		0
19	C		0
20	B		0
21	A		1
22	C		1
23	B		1
24	B		0
25	A		0
26	C		1
27	B		1
28	C		0
29	A		1
30	C		0
31	A		0
32	B		1
33	A		0
34
35
Sheet1

Cell Formulas
Range	Formula
D2	D2	=SUM(C2:C40)
C4:C35	C4	=IFERROR(IF(SUM(CODE($A2:$A4))=198,1,0),"")

 

[Fluff]

Another option

=LET(r,ROWS(A2:A33),SUM(--(MMULT((SEQUENCE(r,,3)>=SEQUENCE(,r))*(SEQUENCE(r)<=SEQUENCE(,r)),CODE(A2:A33))=198)))

 

[Fluff]

If your data is all in one cell, you could use

+Fluff 1.xlsm
	E	F
3
4	CBCABABACABACABBCCBACBBACBCACABA	13
5	BABABCBAB	2
Data

Cell Formulas
Range	Formula
F4:F5	F4	=SUM(SIGN(HEX2DEC(BYROW(MID(E4,SEQUENCE(LEN(E4)-2),3),LAMBDA(r,CONCAT(SORT(MID(r,{1;2;3},1))))))=2748))

 

[Fluff]

Gone slightly OTT on the previous formula, there's no need for the hex2dec function

=SUM(SIGN(BYROW(MID(D4,SEQUENCE(LEN(D4)-2),3),LAMBDA(r,CONCAT(SORT(MID(r,{1;2;3},1)))))="ABC"))